[arch-commits] Commit in 389-ds-base/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Sven-Hendrik Haase svenstaro at archlinux.org
Sun Aug 11 12:50:45 UTC 2019


    Date: Sunday, August 11, 2019 @ 12:50:45
  Author: svenstaro
Revision: 359612

archrelease: copy trunk to extra-x86_64

Added:
  389-ds-base/repos/extra-x86_64/PKGBUILD
    (from rev 359611, 389-ds-base/trunk/PKGBUILD)
Deleted:
  389-ds-base/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  147 ++++++++++++++++++++++++++-----------------------------------
 1 file changed, 63 insertions(+), 84 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-08-11 12:50:41 UTC (rev 359611)
+++ PKGBUILD	2019-08-11 12:50:45 UTC (rev 359612)
@@ -1,84 +0,0 @@
-# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
-# Contributor: Javier Torres <javitonino [at] gmail [dot] com>
-# Contributor: Jameson Pugh <imntreal at gmail.com>
-# Contributor: Xiao-Long Chen <chenxiaolong at cxl.epac.to>
-
-pkgbase=389-ds-base
-pkgname=(389-ds-base python-lib389)
-pkgver=1.4.1.6
-pkgrel=2
-arch=(x86_64)
-url="http://port389.org/"
-license=(GPL)
-depends=(libevent nspr nss net-snmp pam openldap)
-checkdepends=(python-pytest)
-makedepends=(cargo rsync doxygen cmocka python python-setuptools
-             python-argparse-manpage python-argcomplete python-ldap)
-source=("https://releases.pagure.org/389-ds-base/${pkgname}-${pkgver}.tar.bz2")
-sha512sums=('0a943453cbcd8b43b4fdc58563c8802d9270d9a3cf4dcd76e3f77168d45e84b8e07d8df8ddadb09ba9294e7ba7e9304ce329bc37edeb16a9161797c902fadc1c')
-
-prepare() {
-  cd "${pkgbase}-${pkgver}"
-
-  autoreconf -fiv
-}
-
-build() {
-  cd "${pkgbase}-${pkgver}"
-
-  # Build 389-ds-base
-  ./configure \
-    --prefix=/usr \
-    --sysconfdir=/etc \
-    --sbindir=/usr/bin \
-    --localstatedir=/var \
-    --libexecdir=/usr/lib/${pkgbase} \
-    --with-tmpfiles-d=/usr/lib/tmpfiles.d \
-    --with-systemd \
-    --with-systemdsystemunitdir=/usr/lib/systemd/system \
-    --with-systemdsystemconfdir=/etc/systemd/system \
-    --with-journald \
-    --enable-autobind \
-    --enable-cmocka \
-    --with-openldap \
-    --enable-rust
-  make
-
-  # Build python-lib389
-  cd src/lib389
-  python setup.py build
-}
-
-check() {
-  cd "${pkgbase}-${pkgver}"
-  make check
-}
-
-package_389-ds-base() {
-  pkgdesc="389 Directory Server (base)"
-  provides=(libsvrcore.so)
-  optdepends=('python-lib389: Python management scripts')
-  backup=(etc/dirsrv/config/certmap.conf
-          etc/dirsrv/config/ldap-agent.conf
-          etc/dirsrv/config/slapd-collations.conf
-          etc/dirsrv/config/template-initconfig)
-
-  cd "${pkgbase}-${pkgver}"
-  make -j1 DESTDIR="${pkgdir}/" install
-
-  install -dm755 "${pkgdir}"/var/log/${pkgbase}/ "${pkgdir}"/var/lib/${pkgbase}/
-  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
-}
-
-package_python-lib389() {
-  pkgdesc="389 Directory Server (Python management scripts)"
-  depends=(python python-argcomplete python-ldap)
-
-  cd "${pkgbase}-${pkgver}"/src/lib389
-  python setup.py install --skip-build -O1 --root=${pkgdir}
-  mv ${pkgdir}/usr/sbin ${pkgdir}/usr/bin
-
-  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
-}
-
-# vim: set ts=2 sw=2 ft=sh et:

Copied: 389-ds-base/repos/extra-x86_64/PKGBUILD (from rev 359611, 389-ds-base/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-08-11 12:50:45 UTC (rev 359612)
@@ -0,0 +1,63 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Javier Torres <javitonino [at] gmail [dot] com>
+# Contributor: Jameson Pugh <imntreal at gmail.com>
+# Contributor: Xiao-Long Chen <chenxiaolong at cxl.epac.to>
+
+pkgname=389-ds-base
+pkgver=1.4.1.6
+pkgdesc="389 Directory Server (base)"
+pkgrel=3
+arch=(x86_64)
+url="http://port389.org/"
+license=(GPL)
+provides=(libsvrcore.so)
+optdepends=('python-lib389: Python management scripts')
+backup=(etc/dirsrv/config/certmap.conf
+        etc/dirsrv/config/ldap-agent.conf
+        etc/dirsrv/config/slapd-collations.conf
+        etc/dirsrv/config/template-initconfig)
+depends=(libevent nspr nss net-snmp pam openldap)
+makedepends=(cargo rsync doxygen cmocka)
+source=("https://releases.pagure.org/389-ds-base/${pkgname}-${pkgver}.tar.bz2")
+sha512sums=('0a943453cbcd8b43b4fdc58563c8802d9270d9a3cf4dcd76e3f77168d45e84b8e07d8df8ddadb09ba9294e7ba7e9304ce329bc37edeb16a9161797c902fadc1c')
+
+prepare() {
+  cd "${pkgbase}-${pkgver}"
+
+  autoreconf -fiv
+}
+
+build() {
+  cd "${pkgbase}-${pkgver}"
+
+  # Build 389-ds-base
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --sbindir=/usr/bin \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/${pkgbase} \
+    --with-tmpfiles-d=/usr/lib/tmpfiles.d \
+    --with-systemd \
+    --with-systemdsystemunitdir=/usr/lib/systemd/system \
+    --with-systemdsystemconfdir=/etc/systemd/system \
+    --with-journald \
+    --enable-autobind \
+    --enable-cmocka \
+    --with-openldap \
+    --enable-rust
+  make
+}
+
+check() {
+  cd "${pkgbase}-${pkgver}"
+  make check
+}
+
+package() {
+  cd "${pkgbase}-${pkgver}"
+  make -j1 DESTDIR="${pkgdir}/" install
+
+  install -dm755 "${pkgdir}"/var/log/${pkgbase}/ "${pkgdir}"/var/lib/${pkgbase}/
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}



More information about the arch-commits mailing list