[arch-commits] Commit in xfce4-pulseaudio-plugin/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sun Aug 11 23:57:03 UTC 2019
Date: Sunday, August 11, 2019 @ 23:57:02
Author: foutrelis
Revision: 359681
archrelease: copy trunk to staging-x86_64
Added:
xfce4-pulseaudio-plugin/repos/staging-x86_64/
xfce4-pulseaudio-plugin/repos/staging-x86_64/PKGBUILD
(from rev 359680, xfce4-pulseaudio-plugin/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: xfce4-pulseaudio-plugin/repos/staging-x86_64/PKGBUILD (from rev 359680, xfce4-pulseaudio-plugin/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2019-08-11 23:57:02 UTC (rev 359681)
@@ -0,0 +1,50 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
+# Contributor: <alcasa dot mz at gmail dot com>
+# Contributor: twa022 <twa022 at gmail dot com>
+
+pkgname=xfce4-pulseaudio-plugin
+pkgver=0.4.2
+pkgrel=2
+pkgdesc="Pulseaudio plugin for Xfce4 panel"
+arch=('x86_64')
+license=('GPL2')
+url="https://goodies.xfce.org/projects/panel-plugins/xfce4-pulseaudio-plugin"
+groups=('xfce4-goodies')
+depends=('xfce4-panel' 'libpulse' 'libkeybinder3' 'gtk-update-icon-cache' 'libnotify')
+makedepends=('intltool' 'dbus-glib' git xfce4-dev-tools)
+optdepends=('pavucontrol: default pulseaudio mixer')
+_commit=b7a76fa7d7176c4cad4dd432a9629f3fa78ed708 # tags/xfce4-pulseaudio-plugin-0.4.2^0
+source=("git+https://git.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^xfce4-pulseaudio-plugin-//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd "$pkgname"
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --libexecdir=/usr/lib \
+ --localstatedir=/var \
+ --enable-keybinder \
+ --enable-libnotify \
+ --enable-maintainer-mode
+
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+}
+
+package() {
+ cd "$pkgname"
+ make DESTDIR="${pkgdir}" install
+}
More information about the arch-commits
mailing list