[arch-commits] Commit in avr-gcc/repos (2 files)

Anatol Pomozov anatolik at archlinux.org
Mon Aug 12 20:55:23 UTC 2019


    Date: Monday, August 12, 2019 @ 20:55:23
  Author: anatolik
Revision: 499038

archrelease: copy trunk to community-testing-x86_64

Added:
  avr-gcc/repos/community-testing-x86_64/
  avr-gcc/repos/community-testing-x86_64/PKGBUILD
    (from rev 499037, avr-gcc/trunk/PKGBUILD)

----------+
 PKGBUILD |  112 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 112 insertions(+)

Copied: avr-gcc/repos/community-testing-x86_64/PKGBUILD (from rev 499037, avr-gcc/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-08-12 20:55:23 UTC (rev 499038)
@@ -0,0 +1,112 @@
+# Maintainer: schuay <jakob.gruber at gmail.com>
+# Contributor: Brad Fanella <bradfanella at archlinux.us>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+# Contributor: danst0 <danst0 at west.de>
+
+# Build order: avr-binutils -> avr-gcc -> avr-libc
+
+_target=avr
+pkgname=$_target-gcc
+pkgver=9.2.0
+_islver=0.21
+pkgrel=1
+#_snapshot=7-20180125
+pkgdesc='The GNU AVR Compiler Collection'
+arch=(x86_64)
+license=(GPL LGPL FDL custom)
+url='http://gcc.gnu.org/'
+depends=($_target-binutils gcc-libs libmpc)
+optdepends=('avr-libc: Standard C library for Atmel AVR development')
+options=(!emptydirs !strip)
+source=(https://ftp.gnu.org/gnu/gcc/gcc-$pkgver/gcc-$pkgver.tar.xz{,.sig}
+        #ftp://gcc.gnu.org/pub/gcc/snapshots/${_snapshot}/gcc-${_snapshot}.tar.xz
+        http://isl.gforge.inria.fr/isl-${_islver}.tar.bz2
+       )
+sha256sums=('ea6ef08f121239da5695f76c9b33637a118dcf63e24164422231917fa61fb206'
+            'SKIP'
+            'd18ca11f8ad1a39ab6d03d3dcb3365ab416720fcb65b42d69f34f51bf0a0e859')
+validpgpkeys=(33C235A34C46AA3FFB293709A328C3A2C3C45C06) # Jakub Jelinek <jakub at redhat.com>
+
+if [ -n "${_snapshot}" ]; then
+  _basedir=gcc-${_snapshot}
+else
+  _basedir=gcc-${pkgver}
+fi
+
+prepare() {
+    cd ${_basedir}
+}
+
+build() {
+    cd ${srcdir}/${_basedir} 
+
+    # link isl for in-tree build
+    ln -s ../isl-${_islver} isl
+
+    # https://bugs.archlinux.org/task/34629
+    # hack! - some configure tests for header files using "$CPP $CPPFLAGS"
+    sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" {libiberty,gcc}/configure
+
+    echo ${pkgver} > gcc/BASE-VER
+
+    cd ${srcdir}
+    mkdir gcc-build && cd gcc-build
+
+    export CFLAGS_FOR_TARGET='-O2 -pipe'
+    export CXXFLAGS_FOR_TARGET='-O2 -pipe'
+
+    # --disable-linker-build-id   https://bugs.archlinux.org/task/34902
+    # --disable-__cxa_atexit   https://bugs.archlinux.org/task/50848
+    ${srcdir}/${_basedir}/configure \
+                --disable-install-libiberty \
+                --disable-libssp \
+                --disable-libstdcxx-pch \
+                --disable-libunwind-exceptions \
+                --disable-linker-build-id \
+                --disable-nls \
+                --disable-werror \
+                --disable-__cxa_atexit \
+                --enable-checking=release \
+                --enable-clocale=gnu \
+                --enable-gnu-unique-object \
+                --enable-gold \
+                --enable-languages=c,c++ \
+                --enable-ld=default \
+                --enable-lto \
+                --enable-plugin \
+                --enable-shared \
+                --infodir=/usr/share/info \
+                --libdir=/usr/lib \
+                --libexecdir=/usr/lib \
+                --mandir=/usr/share/man \
+                --prefix=/usr \
+                --target=$_target \
+                --with-as=/usr/bin/$_target-as \
+                --with-gnu-as \
+                --with-gnu-ld \
+                --with-ld=/usr/bin/$_target-ld \
+                --with-plugin-ld=ld.gold \
+                --with-system-zlib \
+                --with-isl \
+                --enable-gnu-indirect-function
+
+    make
+}
+
+package() {
+    cd ${srcdir}/gcc-build
+
+    make -j1 DESTDIR=${pkgdir} install
+
+    # Strip debug symbols from libraries; without this, the package size balloons to ~500MB.
+    find ${pkgdir}/usr/lib -type f -name "*.a" \
+        -exec /usr/bin/$_target-strip --strip-debug '{}' \;
+
+    # Install Runtime Library Exception
+    install -Dm644 ${srcdir}/${_basedir}/COPYING.RUNTIME \
+        ${pkgdir}/usr/share/licenses/$_target-gcc/RUNTIME.LIBRARY.EXCEPTION
+
+    rm -r ${pkgdir}/usr/share/man/man7
+    rm -r ${pkgdir}/usr/share/info
+    rm ${pkgdir}/usr/lib/libcc1.*
+}


More information about the arch-commits mailing list