[arch-commits] Commit in haskell-yesod-form/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Aug 14 04:49:58 UTC 2019


    Date: Wednesday, August 14, 2019 @ 04:49:58
  Author: felixonmars
Revision: 499127

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-form/repos/community-staging-x86_64/
  haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD
    (from rev 499126, haskell-yesod-form/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD (from rev 499126, haskell-yesod-form/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-14 04:49:58 UTC (rev 499127)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-form
+pkgname=haskell-yesod-form
+pkgver=1.6.6
+pkgrel=12
+pkgdesc="Form handling support for Yesod Web Framework"
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-byteable' 'haskell-data-default' 'haskell-email-validate'
+         'haskell-network-uri' 'haskell-persistent' 'haskell-resourcet' 'haskell-shakespeare'
+         'haskell-wai' 'haskell-xss-sanitize' 'haskell-yesod-core' 'haskell-yesod-persistent')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('22ba1974c8b5bc906721e89a1be3e33159d44798f9fae5d00fbc76e443e4897d11388c83ba38160151cb5a0d0863a158381e34b290091a8c73c8ad13896875ea')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fnetwork-uri
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list