[arch-commits] Commit in cpp-hocon/repos (2 files)

Levente Polyak anthraxx at archlinux.org
Wed Aug 14 08:39:38 UTC 2019


    Date: Wednesday, August 14, 2019 @ 08:39:38
  Author: anthraxx
Revision: 499184

archrelease: copy trunk to community-testing-x86_64

Added:
  cpp-hocon/repos/community-testing-x86_64/
  cpp-hocon/repos/community-testing-x86_64/PKGBUILD
    (from rev 499183, cpp-hocon/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: cpp-hocon/repos/community-testing-x86_64/PKGBUILD (from rev 499183, cpp-hocon/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2019-08-14 08:39:38 UTC (rev 499184)
@@ -0,0 +1,46 @@
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=cpp-hocon
+pkgver=0.2.1
+pkgrel=3
+pkgdesc="C++ port of the Typesafe Config library"
+arch=('x86_64')
+url="https://github.com/puppetlabs/cpp-hocon"
+license=('APACHE')
+depends=('boost-libs' 'gcc-libs' 'glibc' 'leatherman' 'leatherman_util.so' 'leatherman_locale.so')
+makedepends=('boost' 'cmake' 'leatherman' 'rapidjson')
+provides=('libcpp-hocon.so')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/puppetlabs/cpp-hocon/archive/$pkgver.tar.gz")
+sha512sums=('fcc377da7923b77436a6f2787d5b8b1b573f239de4f059c4a5949cbb1a755fd12024b9155f5e44cf60141181942f3e9a2a8fad07ee0b1d516fe2cd4a88d4ac8b')
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  mkdir -p build
+  cd build
+
+  cmake \
+    -DCMAKE_BUILD_TYPE=None \
+    -DENABLE_CXX_WERROR=OFF \
+    -DCMAKE_INSTALL_PREFIX:PATH=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    ..
+  make
+}
+
+check() {
+  cd "$pkgname-$pkgver"/build
+
+  make test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  make -C build install DESTDIR="$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list