[arch-commits] Commit in libuhd/repos (2 files)

[Kyle Keen]

    Date: Friday, August 16, 2019 @ 05:26:43
  Author: kkeen
Revision: 499697

archrelease: copy trunk to community-staging-x86_64

Added:
  libuhd/repos/community-staging-x86_64/
  libuhd/repos/community-staging-x86_64/PKGBUILD
    (from rev 499696, libuhd/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: libuhd/repos/community-staging-x86_64/PKGBUILD (from rev 499696, libuhd/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-16 05:26:43 UTC (rev 499697)
@@ -0,0 +1,50 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: Dominik Heidler <dheidler at gmail.com>
+
+pkgname=libuhd
+pkgver=3.14.1.0
+pkgrel=1
+pkgdesc="Universal Software Radio Peripheral (USRP) userspace driver"
+arch=('x86_64')
+url="http://www.ettus.com/kb/category/software-documentation/uhd-manual"
+license=('GPL')
+depends=('boost-libs' 'orc' 'libusb')
+optdepends=('python2: usrp utils')
+makedepends=('cmake' 'boost' 'python2-mako')
+# gpsd?  dpdk?
+
+source=("libuhd-$pkgver.tar.gz::https://github.com/EttusResearch/uhd/archive/v$pkgver.tar.gz")
+md5sums=('2eaad9beeff8c6d9716c93d580fb7b1c')
+
+prepare() {
+  cd "$srcdir/uhd-$pkgver"
+  # fix for py2
+  find -name "*.py" -or -name '*.py.in' | xargs sed -i "s|#!/usr/bin/env python$|#!/usr/bin/env python2|"
+}
+
+build() {
+  cd "$srcdir/uhd-$pkgver/host"
+
+  mkdir -p build
+  cd build
+  cmake .. -DCMAKE_INSTALL_PREFIX=/usr/ \
+           -DPYTHON_EXECUTABLE=/usr/bin/python2 \
+           -DENABLE_EXAMPLES=OFF \
+           -DENABLE_UTILS=ON \
+           -DENABLE_TESTS=OFF \
+           -DENABLE_E100=ON \
+           -DENABLE_E300=ON
+  make
+}
+
+check() {
+  cd "$srcdir/uhd-$pkgver/host/build"
+  make test
+}
+
+package() {
+  cd "$srcdir/uhd-$pkgver/host/build"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 "../utils/uhd-usrp.rules" "$pkgdir/usr/lib/udev/rules.d/10-uhd-usrp.rules"
+} 
+