[arch-commits] Commit in chezmoi/repos (extra-x86_64 extra-x86_64/PKGBUILD)

[Daurnimator]

    Date: Friday, August 16, 2019 @ 09:23:06
  Author: daurnimator
Revision: 499830

archrelease: copy trunk to extra-x86_64

Added:
  chezmoi/repos/extra-x86_64/
  chezmoi/repos/extra-x86_64/PKGBUILD
    (from rev 499829, chezmoi/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: chezmoi/repos/extra-x86_64/PKGBUILD (from rev 499829, chezmoi/trunk/PKGBUILD)
===================================================================
--- extra-x86_64/PKGBUILD	                        (rev 0)
+++ extra-x86_64/PKGBUILD	2019-08-16 09:23:06 UTC (rev 499830)
@@ -0,0 +1,37 @@
+# Maintainer: Daurnimator <daurnimator at archlinux.org>
+# Contributor: Tom Payne <twpayne at gmail.com>
+# Contributor:  <godeater at gmail.com>
+
+pkgname=chezmoi
+pkgver=1.6.1
+pkgrel=2
+pkgdesc="Multi-machine dotfile management system"
+arch=('x86_64')
+url='https://github.com/twpayne/chezmoi'
+license=('MIT')
+makedepends=('go-pie' 'git')
+depends=('glibc')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/twpayne/chezmoi/archive/v${pkgver}.tar.gz")
+sha256sums=('ab315e88cc1740468adac51d0e8e57b6b9553b0668e178b44ef32074b791c8e8')
+
+build() {
+  cd "$pkgname-$pkgver"
+
+  go build \
+    -gcflags "all=-trimpath=${PWD}" \
+    -asmflags "all=-trimpath=${PWD}" \
+    -ldflags "-extldflags ${LDFLAGS}" \
+    .
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  install -D "$pkgname" "$pkgdir/usr/bin/$pkgname"
+
+  install -Dm644 completions/chezmoi-completion.bash "$pkgdir/usr/share/bash-completion/completions/chezmoi"
+  install -Dm644 completions/chezmoi.fish "$pkgdir/usr/share/fish/vendor_completions.d/chezmoi.fish"
+  install -Dm644 completions/chezmoi.zsh "$pkgdir/usr/share/zsh/site-functions/_chezmoi"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}