[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, August 17, 2019 @ 03:28:13
  Author: felixonmars
Revision: 499921

addpkg: haskell-dyre 0.8.12-1

Added:
  haskell-dyre/
  haskell-dyre/repos/
  haskell-dyre/trunk/
  haskell-dyre/trunk/PKGBUILD

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Added: haskell-dyre/trunk/PKGBUILD
===================================================================
--- haskell-dyre/trunk/PKGBUILD	                        (rev 0)
+++ haskell-dyre/trunk/PKGBUILD	2019-08-17 03:28:13 UTC (rev 499921)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=dyre
+pkgname=haskell-dyre
+pkgver=0.8.12
+pkgrel=1
+pkgdesc="Dynamic reconfiguration in Haskell"
+url="https://github.com/willdonnelly/dyre"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ghc-paths' 'haskell-executable-path' 'haskell-xdg-basedir'
+         'haskell-io-storage')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('157f1d20dd7a0bbad46044722a4d0e291df09dede715417cf20b18391cb13b52fc25486f99d604d3c279a3f86fc3fc405466099e995190fcbe8aad3cbdb1220e')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}