[arch-commits] Commit in scrapy/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Aug 18 18:06:08 UTC 2019


    Date: Sunday, August 18, 2019 @ 18:06:08
  Author: felixonmars
Revision: 500102

archrelease: copy trunk to community-testing-any

Added:
  scrapy/repos/community-testing-any/
  scrapy/repos/community-testing-any/PKGBUILD
    (from rev 500101, scrapy/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: scrapy/repos/community-testing-any/PKGBUILD (from rev 500101, scrapy/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2019-08-18 18:06:08 UTC (rev 500102)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: PyroDevil <p dot devil at gmail dot com>
+# Contributor: Anibal Pacheco <apacheco.uy at gmail.com>
+
+pkgname=scrapy
+pkgver=1.7.3
+pkgrel=1
+pkgdesc="A fast high-level scraping and web crawling framework."
+arch=('any')
+license=('BSD')
+url="http://scrapy.org"
+depends=('python-twisted' 'libxml2' 'python-w3lib' 'python-lxml' 'python-six' 'python-queuelib'
+         'python-setuptools' 'python-cssselect' 'python-pyopenssl' 'python-parsel'
+         'python-pydispatcher' 'python-service-identity')
+checkdepends=('python-pytest-runner' 'python-pillow' 'python-testfixtures' 'python-botocore'
+              'python-jmespath' 'mitmproxy')
+optdepends=('ipython: for enhanced support of the interactive scraping shell')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/scrapy/scrapy/archive/$pkgver.tar.gz")
+sha512sums=('2bd1762304f960727f1ae2a8fa1d26d8ab0e310a457f646316a31e5b7c647ad68f28420a16e6a1fbc97b424e0aaf8539ba35a5bcb595ebcc0bd153a6aa631cd4')
+
+build() {
+  cd scrapy-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd scrapy-$pkgver
+  python setup.py pytest --addopts tests
+}
+
+package() {
+  cd scrapy-$pkgver
+  python setup.py install -O1 --root="$pkgdir"
+
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -D -m644 README.rst "$pkgdir"/usr/share/doc/$pkgname/README.rst
+  install -D -m644 docs/intro/install.rst "$pkgdir"/usr/share/doc/$pkgname/INSTALL.rst
+}



More information about the arch-commits mailing list