[arch-commits] Commit in cantor (trunk trunk trunk/PKGBUILD)

[Felix Yan]

    Date: Tuesday, August 20, 2019 @ 08:40:49
  Author: felixonmars
Revision: 360203

upgpkg: cantor 19.08.0-1

KDE Applications 19.08.0

Added:
  cantor/trunk/
  cantor/trunk/PKGBUILD
Deleted:
  cantor/trunk/

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD	                        (rev 0)
+++ trunk/PKGBUILD	2019-08-20 08:40:49 UTC (rev 360203)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=cantor
+pkgver=19.08.0
+pkgrel=1
+pkgdesc="KDE Frontend to Mathematical Software"
+url="https://kde.org/applications/education/cantor/"
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdeedu)
+depends=(analitza libspectre kpty ktexteditor knewstuff libqalculate hicolor-icon-theme discount qt5-xmlpatterns)
+makedepends=(extra-cmake-modules python python2 kdoctools luajit r julia)
+optdepends=('maxima: Maxima backend'
+            'octave: Octave backend'
+            'r: R backend'
+            'luajit: LUA backend'
+            'python: Python 3 backend'
+	    'python2: Python 2 backend'
+            'sagemath: SageMath backend'
+            'julia: Julia backend')
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('b1d1a735e83ca03d51b79f1fc59612153e94b274d716d65ff3fa94ffdd2f3adc'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DPYTHON_INCLUDE_DIR=/usr/include/python2.7 \
+    -DPYTHON_LIBRARY=/usr/lib/libpython2.7.so
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}


Property changes on: cantor/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property