[arch-commits] Commit in kdenlive (trunk trunk trunk/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Tue Aug 20 09:02:21 UTC 2019
Date: Tuesday, August 20, 2019 @ 09:02:19
Author: felixonmars
Revision: 360353
upgpkg: kdenlive 19.08.0-1
KDE Applications 19.08.0
Added:
kdenlive/trunk/
kdenlive/trunk/PKGBUILD
Deleted:
kdenlive/trunk/
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD (rev 0)
+++ trunk/PKGBUILD 2019-08-20 09:02:19 UTC (rev 360353)
@@ -0,0 +1,47 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Zuf <kontakt.zuf at gmail.com>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=kdenlive
+pkgver=19.08.0
+pkgrel=1
+pkgdesc="A non-linear video editor for Linux using the MLT video framework"
+arch=(x86_64)
+url="https://www.kdenlive.org/"
+license=(GPL)
+groups=(kde-applications kdemultimedia)
+depends=(knewstuff knotifyconfig kfilemetadata purpose mlt rttr breeze-icons frei0r-plugins)
+makedepends=(extra-cmake-modules kdoctools v4l-utils)
+optdepends=('ffmpeg: for FFmpeg plugin'
+ 'cdrtools: for creation of DVD ISO images'
+ 'dvdauthor: for creation of DVD'
+ 'dvgrab: for firewire capture'
+ 'recordmydesktop: for screen capture'
+ 'xine-ui: for DVD preview'
+ 'vlc: for DVD preview'
+ 'plasma-desktop: theme configuration')
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('aec48103409499da7ba9477ce349c00913d3bc8d8a04c481aed962a2ffeeefce'
+ 'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid at kde.org>
+ F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+}
+
+package() {
+ cd build
+ make DESTDIR="$pkgdir" install
+}
Property changes on: kdenlive/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list