[arch-commits] Commit in haskell-turtle/repos (2 files)

[Felix Yan]

    Date: Friday, August 23, 2019 @ 03:52:59
  Author: felixonmars
Revision: 500789

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-turtle/repos/community-staging-x86_64/
  haskell-turtle/repos/community-staging-x86_64/PKGBUILD
    (from rev 500788, haskell-turtle/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-turtle/repos/community-staging-x86_64/PKGBUILD (from rev 500788, haskell-turtle/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-23 03:52:59 UTC (rev 500789)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=turtle
+pkgname=haskell-turtle
+pkgver=1.5.14
+pkgrel=18
+pkgdesc="Shell programming, Haskell-style"
+url="https://github.com/Gabriel439/Haskell-Turtle-Library"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-wl-pprint' 'haskell-async' 'haskell-clock' 'haskell-exceptions'
+         'haskell-foldl' 'haskell-hostname' 'haskell-managed' 'haskell-optparse-applicative'
+         'haskell-optional-args' 'haskell-system-fileio' 'haskell-system-filepath'
+         'haskell-temporary' 'haskell-unix-compat')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a07c1db409d99ef5f844abce742b4ffcb467c883808881a255bb30055b2646f7ca943ed5fe59b7248e7a34170a05c0af61b23e063b87d4ad272c1413fa700900')
+
+prepare() {
+    sed -i 's/]/, "-dynamic"]/' $_hkgname-$pkgver/test/Main.hs
+    sed -i -e '/semigroups/d' -e 's/< *0.8/<1/' $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}