[arch-commits] Commit in scribus/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Fri Aug 23 08:23:57 UTC 2019
Date: Friday, August 23, 2019 @ 08:23:57
Author: foutrelis
Revision: 501236
archrelease: copy trunk to community-staging-x86_64
Added:
scribus/repos/community-staging-x86_64/
scribus/repos/community-staging-x86_64/PKGBUILD
(from rev 501235, scribus/trunk/PKGBUILD)
----------+
PKGBUILD | 66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 66 insertions(+)
Copied: scribus/repos/community-staging-x86_64/PKGBUILD (from rev 501235, scribus/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2019-08-23 08:23:57 UTC (rev 501236)
@@ -0,0 +1,66 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
+# Contributor: Ben <ben at benmazer.net>
+
+pkgname=scribus
+pkgver=1.5.5
+pkgrel=3
+pkgdesc="Desktop publishing software"
+arch=(x86_64)
+url="https://www.scribus.net/"
+license=(GPL)
+depends=(qt5-base harfbuzz-icu poppler python2 hunspell podofo openscenegraph
+ libcdr libfreehand libmspub libpagemaker libqxp libvisio libzmf) # graphicsmagick
+makedepends=(cmake boost mesa qt5-tools)
+optdepends=('tk: scripts based on tkinter'
+ 'hyphen-lang: hyphenation patterns for desired languages')
+source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha256sums=(7908b21a6ce843269f58cedf5f8f791893257e6201cce5fbddc70daca2fe3f71 SKIP)
+validpgpkeys=(5086B8D68E70FDDF4C40045AEF7B95E7F60166DA # Peter Linnell <plinnell at scribus.net>
+ 757F5E9B13DD648887AD50092D47C099E782504E # The Scribus Team (www.scribus.net) <the_scribus_team at scribus.net>
+ 6558BE84D27273A438A151198BEA48118AEBEE64) # Craig Bradney <cbradney at zipworld.com.au>
+
+prepare() {
+ cd ${pkgname}-${pkgver}
+
+ # Fix python name
+ sed \
+ -e 's|#!/usr/bin/python|#!/usr/bin/python2|' \
+ -e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+ -i scribus/plugins/scriptplugin/{samples,scripts}/*
+
+ mkdir -p build
+}
+
+build() {
+ cd ${pkgname}-${pkgver}/build
+ cmake .. \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_SKIP_RPATH=ON
+ # FS#59800
+ #-DWANT_GRAPHICSMAGICK=1
+ make
+}
+
+package() {
+ cd ${pkgname}-${pkgver}/build
+
+ make DESTDIR="${pkgdir}" install
+
+ cd ..
+
+ install -Dm644 scribus.desktop -t "${pkgdir}"/usr/share/applications
+
+ for i in 16x16 32x32 128x128 256x256 512x512 1024x1024
+ do
+ install -Dm644 resources/iconsets/artwork/icon_${i}.png "${pkgdir}"/usr/share/icons/hicolor/${i}/apps/scribus.png
+ done
+
+ # Use system hyphen
+ rm -rf "${pkgdir}"/usr/share/scribus/dicts/hyph
+ ln -sf /usr/share/hyphen "${pkgdir}"/usr/share/scribus/dicts/hyph
+}
More information about the arch-commits
mailing list