[arch-commits] Commit in python-cvxopt/repos (2 files)

[Evangelos Foutras]

    Date: Saturday, August 24, 2019 @ 21:42:53
  Author: foutrelis
Revision: 501578

archrelease: copy trunk to community-staging-x86_64

Added:
  python-cvxopt/repos/community-staging-x86_64/
  python-cvxopt/repos/community-staging-x86_64/PKGBUILD
    (from rev 501577, python-cvxopt/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-cvxopt/repos/community-staging-x86_64/PKGBUILD (from rev 501577, python-cvxopt/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-24 21:42:53 UTC (rev 501578)
@@ -0,0 +1,58 @@
+# Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+# Contributor: BinkyTheClown <binky_at_archlinux_dot_us>
+# Contributor: Julien Ugon <bzklrm at gmail dot com>
+# Contributor: Lex Black <autumn-wind at web dot de>
+# Contributor: Gustavao A. Gomez Farhat <gustavo_gomez_farhat_at_gmail_dot_com>
+
+pkgbase=python-cvxopt
+pkgname=('python2-cvxopt' 'python-cvxopt')
+pkgver=1.2.3
+pkgrel=2
+pkgdesc="A free software package for convex optimization written in Python"
+url="https://cvxopt.org/"
+arch=('x86_64')
+license=('GPL3')
+makedepends=('gsl' 'fftw' 'glpk' 'dsdp' 'python-setuptools' 'python2-setuptools' 'suitesparse')
+optdepends=('gsl: for custom random number generators'
+            'fftw: for FFTW interface'
+            'glpk: solver for linear cone and PWL programming problems'
+            'dsdp: solver for linear cone semidefinite programming problems')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/cvxopt/cvxopt/archive/${pkgver}.tar.gz")
+sha1sums=('fa566af5ff09088d2a73d219febea1d896c06c9d')
+
+prepare() {
+  cd "$srcdir"
+  cp -a cvxopt-${pkgver} cvxopt-py2-${pkgver}
+}
+
+build() {
+  cd "$srcdir"/cvxopt-$pkgver
+
+  for lib in GSL FFTW GLPK DSDP; do
+    eval "export $'CVXOPT_BUILD_$lib'=1"
+  done
+
+  msg "Building Python2"
+  cd "$srcdir"/cvxopt-py2-${pkgver}
+  python2 setup.py build
+
+  msg "Building Python3"
+  cd "$srcdir"/cvxopt-${pkgver}
+  python setup.py build
+}
+
+package_python2-cvxopt() {
+  depends=("python2" "suitesparse")
+
+  cd "$srcdir"/cvxopt-py2-${pkgver}
+
+  python2 setup.py install --skip-build --root="$pkgdir" --optimize=1
+}
+
+package_python-cvxopt() {
+  depends=("python" "suitesparse")
+
+  cd "$srcdir"/cvxopt-${pkgver}
+
+  python setup.py install --skip-build --root="$pkgdir" --optimize=1
+}