[arch-commits] Commit in haskell-pandoc-types/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Aug 25 13:42:58 UTC 2019


    Date: Sunday, August 25, 2019 @ 13:42:57
  Author: felixonmars
Revision: 501680

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-pandoc-types/repos/community-staging-x86_64/
  haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD
    (from rev 501679, haskell-pandoc-types/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-pandoc-types/repos/community-staging-x86_64/PKGBUILD (from rev 501679, haskell-pandoc-types/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-25 13:42:57 UTC (rev 501680)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=pandoc-types
+pkgname=haskell-pandoc-types
+pkgver=1.17.6
+pkgrel=1
+pkgdesc="Types for representing a structured document"
+url="https://pandoc.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-quickcheck' 'haskell-syb')
+makedepends=('ghc' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2' 'haskell-hunit' 'haskell-string-qq')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('e6aa1e41d1f8b47fef7190733889cebf87b338cdbf6b6f7e9ad6d8d3bc96de05b886e85175d7cba63654518529163c430fc5fd76b0e2f26e1c2f66d089149e36')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list