[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Mon Aug 26 05:15:25 UTC 2019


    Date: Monday, August 26, 2019 @ 05:15:25
  Author: felixonmars
Revision: 501800

addpkg: python-maxminddb 1.4.1-1

Added:
  python-maxminddb/
  python-maxminddb/repos/
  python-maxminddb/trunk/
  python-maxminddb/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: python-maxminddb/trunk/PKGBUILD
===================================================================
--- python-maxminddb/trunk/PKGBUILD	                        (rev 0)
+++ python-maxminddb/trunk/PKGBUILD	2019-08-26 05:15:25 UTC (rev 501800)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-maxminddb
+pkgver=1.4.1
+_testdatacommit=90c7fb95d67ee03ca7fc487fb69f525bcc19a671
+pkgrel=1
+pkgdesc="Reader for the MaxMind DB format"
+url="https://github.com/maxmind/MaxMind-DB-Reader-python"
+license=('Apache')
+arch=('x86_64')
+depends=('python' 'libmaxminddb')
+makedepends=('python-setuptools')
+checkdepends=('python-nose' 'python-mock')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/maxmind/MaxMind-DB-Reader-python/archive/v$pkgver.tar.gz"
+        https://github.com/maxmind/MaxMind-DB/archive/$_testdatacommit.tar.gz)
+sha512sums=('94bee89a0ef9d24f937f12f79dc8b9686be46ba3aeedc5538cc0c2ff4379ad2eb0bb84914849d3baa9120d4bbdb3abc215e30efd237a2c6d5fc0161e7e40c0d6'
+            '6693bc2d100524c7fce61ff556132a78f33793f3e4bd4756661cfdf385198d15f3a0044346d46fef6d50fac2f6ecc755d9bebea4b22edb5be834cd39f64e7434')
+
+prepare() {
+  cd MaxMind-DB-Reader-python-$pkgver
+  rmdir tests/data
+  ln -s "$srcdir"/MaxMind-DB-$_testdatacommit tests/data
+}
+
+build() {
+  cd MaxMind-DB-Reader-python-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd MaxMind-DB-Reader-python-$pkgver
+  python setup.py nosetests
+}
+
+package() {
+  cd MaxMind-DB-Reader-python-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}



More information about the arch-commits mailing list