[arch-commits] Commit in haskell-test-framework/repos (2 files)

Felix Yan felixonmars at archlinux.org
Mon Aug 26 09:22:37 UTC 2019


    Date: Monday, August 26, 2019 @ 09:22:36
  Author: felixonmars
Revision: 501997

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-test-framework/repos/community-staging-x86_64/
  haskell-test-framework/repos/community-staging-x86_64/PKGBUILD
    (from rev 501996, haskell-test-framework/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-test-framework/repos/community-staging-x86_64/PKGBUILD (from rev 501996, haskell-test-framework/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-26 09:22:36 UTC (rev 501997)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=test-framework
+pkgname=haskell-test-framework
+pkgver=0.8.2.0
+pkgrel=31
+pkgdesc="Framework for running and organising tests, with HUnit and QuickCheck support"
+url="https://batterseapower.github.io/test-framework/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-ansi-wl-pprint' 'haskell-hostname'
+         'haskell-old-locale' 'haskell-random' 'haskell-regex-posix' 'haskell-xml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-libxml')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('d8e7ea274819a1b49b9f938df527d22c808f456d25b84f03173ed57dddd39c230fb037a57ce90c38f571801ee38e86bed6826df1c93f184e4a803c72ce5f41e4')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/semigroups/d' -e 's/< *0.6/<1/' -e 's/< *0.9/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    # --enable-tests \  Doesn't work with new QuickCheck
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list