[arch-commits] Commit in mkvtoolnix/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Maxime Gauduin alucryd at archlinux.org
Mon Aug 26 17:00:47 UTC 2019


    Date: Monday, August 26, 2019 @ 17:00:47
  Author: alucryd
Revision: 361237

archrelease: copy trunk to staging-x86_64

Added:
  mkvtoolnix/repos/staging-x86_64/
  mkvtoolnix/repos/staging-x86_64/PKGBUILD
    (from rev 361236, mkvtoolnix/trunk/PKGBUILD)

----------+
 PKGBUILD |   96 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 96 insertions(+)

Copied: mkvtoolnix/repos/staging-x86_64/PKGBUILD (from rev 361236, mkvtoolnix/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-08-26 17:00:47 UTC (rev 361237)
@@ -0,0 +1,96 @@
+# Maintainer: Giovanni Scafora <giovanni at archlinux.org>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: xduugu <xduugu at gmx.com>
+
+pkgbase=mkvtoolnix
+pkgname=(
+  mkvtoolnix-cli
+  mkvtoolnix-gui
+)
+pkgver=37.0.0
+pkgrel=2
+pkgdesc='Set of tools to create, edit and inspect Matroska files'
+arch=(x86_64)
+url=https://www.bunkus.org/videotools/mkvtoolnix/
+license=('GPL')
+makedepends=(
+  boost
+  boost-libs
+  cmark
+  docbook-xsl
+  file
+  flac
+  fmt
+  git
+  libebml
+  libmatroska
+  libogg
+  libvorbis
+  qt5-multimedia
+  ruby-rake
+  zlib
+)
+source=(git+https://gitlab.com/mbunkus/mkvtoolnix.git#tag=release-${pkgver})
+sha256sums=('SKIP')
+
+prepare() {
+  cd mkvtoolnix
+
+  ./autogen.sh
+}
+
+build() {
+  cd mkvtoolnix
+
+  ./configure \
+    --prefix=/usr \
+    --disable-qt
+  rake apps:mkvinfo $MAKEFLAGS
+  mv src/mkvinfo{,-cli}
+
+  ./configure \
+    --prefix=/usr \
+    --disable-update-check
+  rake $MAKEFLAGS
+}
+
+package_mkvtoolnix-cli() {
+  depends=(
+    boost-libs
+    file
+    flac
+    libogg
+    zlib
+    libebml.so
+    libfmt.so
+    libmatroska.so
+    libvorbis.so
+  )
+
+  cd mkvtoolnix
+
+  rake DESTDIR="${pkgdir}" install
+  install -m 755 src/mkvinfo-cli "${pkgdir}"/usr/bin/mkvinfo
+  rm -rf "${pkgdir}"/usr/share/{applications,icons,metainfo,mime,mkvtoolnix}
+  find "${pkgdir}" -name mkvtoolnix-gui* -delete
+}
+
+package_mkvtoolnix-gui() {
+  depends=(
+    cmark
+    hicolor-icon-theme
+    mkvtoolnix-cli
+    qt5-base
+    qt5-multimedia
+  )
+
+  cd mkvtoolnix
+
+  rake DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/share/locale
+  for t in mkv{extract,info,merge,propedit}; do
+    find "${pkgdir}" -name $t* -delete
+  done
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list