[arch-commits] Commit in python-numpy/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, August 27, 2019 @ 10:57:58
  Author: felixonmars
Revision: 361271

archrelease: copy trunk to testing-x86_64

Added:
  python-numpy/repos/testing-x86_64/
  python-numpy/repos/testing-x86_64/PKGBUILD
    (from rev 361270, python-numpy/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: python-numpy/repos/testing-x86_64/PKGBUILD (from rev 361270, python-numpy/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-08-27 10:57:58 UTC (rev 361271)
@@ -0,0 +1,42 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve> 
+
+pkgname=python-numpy
+pkgver=1.17.1
+pkgrel=1
+pkgdesc="Scientific tools for Python"
+arch=('x86_64')
+license=('custom')
+url="https://www.numpy.org/"
+depends=('cblas' 'lapack' 'python')
+optdepends=('python-nose: testsuite'
+            'openblas: faster linear algebra')
+makedepends=('python-setuptools' 'gcc-fortran' 'python-nose' 'cython')
+checkdepends=('python-pytest')
+options=('staticlibs')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/numpy/numpy/archive/v$pkgver.tar.gz")
+sha512sums=('9392c7e09f50b6e9b7d9eea0c07c4cc81f4eef182efc09d8351b9f516e58465880fe943d7e2f548b5246cc92ffec3e572eab3eb859599e1d4e31bfba77d1e1ac')
+
+build() {
+  cd numpy-$pkgver
+  python setup.py build
+}
+
+check() {
+  # TODO: Fix fortran tests here (it works fine after installation)
+
+  cd numpy-$pkgver
+  python setup.py install --root="$PWD/tmp_install" --optimize=1
+  cd "$PWD/tmp_install"
+  PATH="$PWD/usr/bin:$PATH" PYTHONPATH="$PWD/usr/lib/python3.7/site-packages:$PYTHONPATH" python -c 'import numpy; numpy.test()'
+}
+
+package() {
+  cd numpy-$pkgver
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+
+  install -m755 -d "${pkgdir}/usr/share/licenses/python-numpy"
+  install -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/python-numpy/"
+}