[arch-commits] Commit in python-progressbar/trunk (PKGBUILD)

[David Runge]

    Date: Tuesday, August 27, 2019 @ 17:05:11
  Author: dvzrv
Revision: 503312

upgpkg: python-progressbar 3.43.1-1

Upgrading to 3.43.1. Updating maintainer. Switching to pypi for sources upstream. Running pytest in check() (by removing custom pytest.ini) with few exceptions, that are tracked in a ticket upstream. Installing docs. Minor cleanups.

Modified:
  python-progressbar/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++----------------
 1 file changed, 40 insertions(+), 16 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2019-08-27 16:14:57 UTC (rev 503311)
+++ PKGBUILD	2019-08-27 17:05:11 UTC (rev 503312)
@@ -1,30 +1,54 @@
-# Maintainer: Maxim Andersson <thesilentboatman at gmail.com>
-# Co-Maintainer: NicoHood <archlinux {cat} nicohood {dog} de>
-# PGP ID: 97312D5EB9D7AE7D0BD4307351DAE9B7C1AE9161
+# Maintainer: David Runge <dave at sleepmap.de>
+# Contributor: Maxim Andersson <thesilentboatman at gmail.com>
+# Contributor: NicoHood <archlinux {cat} nicohood {dog} de>
 
-_pkgname=python-progressbar
+_name=progressbar2
 pkgname=python-progressbar
 pkgdesc="A progress bar for Python"
-pkgver=3.42.0
+pkgver=3.43.1
 pkgrel=1
 url="https://github.com/WoLpH/python-progressbar"
 license=('BSD')
-arch=("any")
-depends=('python' 'python-utils')
-makedepends=('python' 'python-setuptools' 'python-utils')
-source=("${_pkgname}-${pkgver}.tar.xz::https://github.com/WoLpH/python-progressbar/releases/download/v${pkgver}/python-progressbar-v${pkgver}.tar.xz"
-        "${_pkgname}-${pkgver}.tar.xz.asc::https://github.com/WoLpH/python-progressbar/releases/download/v${pkgver}/python-progressbar-v${pkgver}.tar.xz.asc")
-sha512sums=('fefcf9c211413b108de4aac18470a2335a55cf01aca29df01d9a92746320efc656b63d837af9d90fcf4c3078c4af5b451048be1017b0a2af9843f5311bd355f0'
+arch=('any')
+depends=('python-six' 'python-utils')
+makedepends=('python-setuptools' 'python-sphinx')
+checkdepends=('python-pytest' 'python-freezegun')
+source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz"{,.asc})
+sha512sums=('57da1f804e4e3929751b9d27b3f6dc03df65dbf6d567a83d26c6e32dcba22592af1d1153fa3da9f764d11941db2372f22c04d45f963b420e58084d18a15db8c7'
             'SKIP')
 validpgpkeys=('149325FD15904E9C4EB89E95E81444E9CE1F695D') # Rick van Hattem <wolph at wol.ph>
 
+prepare() {
+  mv -v "${_name}-${pkgver}" "${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+  # don't care about custom pytest config
+  rm -v pytest.ini
+}
+
 build() {
-    cd "${srcdir}/${_pkgname}-v${pkgver}"
-    python setup.py build
+  cd "${pkgname}-${pkgver}"
+  python setup.py build
 }
 
+check() {
+  cd "${pkgname}-${pkgver}"
+  export PYTHONPATH="${PWD}/build:${PYTHONPATH}"
+  # disabling tests not honoring PYTHONPATH:
+  # https://github.com/WoLpH/python-progressbar/issues/201
+  py.test -k 'not test_non_timed \
+              and not test_context_wrapper \
+              and not test_rapid_updates \
+              and not test_generator_example \
+              and not test_list_example'
+}
+
 package() {
-    cd "${srcdir}/${_pkgname}-v${pkgver}"
-    python setup.py install --skip-build --root="${pkgdir}" --optimize=1
-    install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --skip-build \
+                          --optimize=1 \
+                          --prefix=/usr \
+                          --root="${pkgdir}"
+  install -vDm 644 {CHANGES,CONTRIBUTING,README}.rst \
+    -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
 }