[arch-commits] Commit in haskell-bifunctors/repos (2 files)

[Felix Yan]

    Date: Wednesday, August 28, 2019 @ 06:09:44
  Author: felixonmars
Revision: 503479

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-bifunctors/repos/community-staging-x86_64/
  haskell-bifunctors/repos/community-staging-x86_64/PKGBUILD
    (from rev 503478, haskell-bifunctors/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-bifunctors/repos/community-staging-x86_64/PKGBUILD (from rev 503478, haskell-bifunctors/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-08-28 06:09:44 UTC (rev 503479)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=bifunctors
+pkgname=haskell-bifunctors
+pkgver=5.5.5
+pkgrel=1
+pkgdesc="Bifunctors"
+url="https://github.com/ekmett/bifunctors/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-comonad' 'haskell-tagged'
+         'haskell-th-abstraction')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7d395d7602c217f7dfa94f9d11b4018130f8cffc9c17476dd7eb564af9bb76a5208eac180d0cd7303a4c98f7b2867dbf3817d62c0e675a2dd34c06f0ae85a227')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -ftagged -f-semigroups
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}