[arch-commits] Commit in (4 files)
Maxime Gauduin
alucryd at archlinux.org
Fri Aug 30 12:28:39 UTC 2019
Date: Friday, August 30, 2019 @ 12:28:38
Author: alucryd
Revision: 505216
add hyperscan
Added:
hyperscan/
hyperscan/trunk/
hyperscan/trunk/.SRCINFO
hyperscan/trunk/PKGBUILD
----------+
.SRCINFO | 17 +++++++++++++++++
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 63 insertions(+)
Added: hyperscan/trunk/.SRCINFO
===================================================================
--- hyperscan/trunk/.SRCINFO (rev 0)
+++ hyperscan/trunk/.SRCINFO 2019-08-30 12:28:38 UTC (rev 505216)
@@ -0,0 +1,17 @@
+pkgbase = hyperscan
+ pkgdesc = High-performance regular expression matching library
+ pkgver = 5.2.0
+ pkgrel = 1
+ url = https://www.hyperscan.io
+ arch = x86_64
+ license = BSD
+ makedepends = boost
+ makedepends = cmake
+ makedepends = git
+ makedepends = python
+ makedepends = ragel
+ source = git+https://github.com/intel/hyperscan.git#tag=v5.2.0
+ sha256sums = SKIP
+
+pkgname = hyperscan
+
Added: hyperscan/trunk/PKGBUILD
===================================================================
--- hyperscan/trunk/PKGBUILD (rev 0)
+++ hyperscan/trunk/PKGBUILD 2019-08-30 12:28:38 UTC (rev 505216)
@@ -0,0 +1,46 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Alireza Ayinmehr <alireza.darksun at gmail.com>
+# Contributor: Maxwell Pray a.k.a. Synthead <synthead at gmail.com>
+# Contributor: JSkier <jskier at gmail dot com>
+# Contributor: Ivan Shapovalov <intelfx at intelfx.name>
+
+pkgname=hyperscan
+pkgver=5.2.0
+pkgrel=1
+pkgdesc='High-performance regular expression matching library'
+arch=(x86_64)
+url=https://www.hyperscan.io
+license=(BSD)
+makedepends=(
+ boost
+ cmake
+ git
+ python
+ ragel
+)
+source=(git+https://github.com/intel/hyperscan.git#tag=v${pkgver})
+sha256sums=(SKIP)
+
+prepare() {
+ if [[ -d build ]]; then
+ rm -rf build
+ fi
+ mkdir build
+}
+
+build() {
+ cd build
+
+ cmake ../hyperscan \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_STATIC_AND_SHARED=ON
+ make
+}
+
+package() {
+ make DESTDIR="$pkgdir" -C build install
+ install -Dm 644 hyperscan/COPYING -t "${pkgdir}"/usr/share/licenses/hyperscan/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list