[arch-commits] Commit in haskell-sbv/repos (2 files)

[Felix Yan]

    Date: Monday, December 2, 2019 @ 22:23:35
  Author: felixonmars
Revision: 534890

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-sbv/repos/community-staging-x86_64/
  haskell-sbv/repos/community-staging-x86_64/PKGBUILD
    (from rev 534889, haskell-sbv/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-sbv/repos/community-staging-x86_64/PKGBUILD (from rev 534889, haskell-sbv/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-02 22:23:35 UTC (rev 534890)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=sbv
+pkgname=haskell-sbv
+pkgver=8.4
+pkgrel=3
+pkgdesc="SMT Based Verification: Symbolic Haskell theorem prover using SMT solving"
+url="https://leventerkok.github.com/sbv"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ghc' 'haskell-quickcheck' 'haskell-cracknum' 'haskell-async'
+         'haskell-random' 'haskell-syb' 'haskell-generic-deriving')
+makedepends=('ghc' 'haskell-doctest' 'haskell-glob' 'hlint' 'haskell-tasty' 'haskell-tasty-golden'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('49323762cc9ca53ba117ab417cad354c271877c09a683182ddd9a189e9db6bf8008b4fa50667ecc847c397ce93cb1eeebfbb10518753981d5995354c98a3ba75')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}