[arch-commits] Commit in python-aws-xray-sdk/repos (2 files)

[Chih-Hsuan Yen]

    Date: Saturday, December 7, 2019 @ 03:21:27
  Author: yan12125
Revision: 536133

archrelease: copy trunk to community-testing-any

Added:
  python-aws-xray-sdk/repos/community-testing-any/
  python-aws-xray-sdk/repos/community-testing-any/PKGBUILD
    (from rev 536132, python-aws-xray-sdk/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: python-aws-xray-sdk/repos/community-testing-any/PKGBUILD (from rev 536132, python-aws-xray-sdk/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2019-12-07 03:21:27 UTC (rev 536133)
@@ -0,0 +1,40 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+pkgname=python-aws-xray-sdk
+_pkgname=aws-xray-sdk-python
+pkgver=2.4.3
+pkgrel=1
+pkgdesc='AWS X-Ray SDK for Python'
+arch=(any)
+url='https://github.com/aws/aws-xray-sdk-python'
+license=(Apache)
+makedepends=(python-setuptools python-pypandoc)
+depends=(python python-botocore python-future python-jsonpickle python-wrapt)
+checkdepends=(python-flask-sqlalchemy python-pynamodb python-pytest python-aiohttp
+              python-pytest-aiohttp python-testing.postgresql python-psycopg2
+              python-pg8000 python-requests python-aiobotocore)
+# Not using PyPI source tarball as it does not include tests
+source=("https://github.com/aws/aws-xray-sdk-python/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('adb528c7c092293613484ca28c5466c79889ff6035493681daf9fbde9ba95b3a')
+
+build() {
+  cd $_pkgname-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  export AWS_SECRET_ACCESS_KEY=fake_key
+  export AWS_ACCESS_KEY_ID=fake_id
+
+  # the test suite is not compatible with Django 2.x yet
+  # https://github.com/aws/aws-xray-sdk-python/issues/85
+  pytest -v --ignore tests/ext/django
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}