[arch-commits] Commit in whipper/trunk (PKGBUILD)

[Christian Rebischke]

    Date: Saturday, December 7, 2019 @ 15:02:17
  Author: shibumi
Revision: 536281

upgpkg: whipper 0.9.0-1 python3 migration

In this release whipper 0.9.0 migrated to python3.

Modified:
  whipper/trunk/PKGBUILD

----------+
 PKGBUILD |   75 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 36 insertions(+), 39 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2019-12-07 14:29:08 UTC (rev 536280)
+++ PKGBUILD	2019-12-07 15:02:17 UTC (rev 536281)
@@ -1,5 +1,5 @@
-# Maintainer: Christian Rebischke <Chris.Rebischke at archlinux.org>
-# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer : Christian Rebischke <Chris.Rebischke at archlinux.org>
+# Maintainer : Bruno Pagani <archange at archlinux.org>
 # Contributor: Frederik "Freso" S. Olesen <archlinux at freso.dk>
 # Contributor: Bastien Traverse <firstname at lastname dot email>
 # Contributor: Samantha Baldwin <fuhsaz+git at cryptic.li>
@@ -9,51 +9,48 @@
 # Contributor: Mantas Mikulėnas <grawity at gmail.com>
 
 pkgname=whipper
-pkgver=0.8.0
-pkgrel=2
-pkgdesc="Unix CD ripper aiming for accuracy over speed -- forked from morituri"
-arch=(x86_64)
+pkgver=0.9.0
+pkgrel=1
+pkgdesc="A Unix CD ripper aiming for accuracy over speed -- forked from morituri"
+arch=('x86_64')
 url="https://github.com/whipper-team/whipper"
-license=(GPL3)
+license=('GPL3')
 depends=(
-    libcdio-paranoia              # for the actual ripping
-    cdrdao                        # for session, TOC, pregap, and ISRC extraction
-    libsndfile                    # for reading wav files (pulls in flac, also required for reading flac files)
-    python2-gobject
-    python2-mutagen               # for metadata handling
-    python2-musicbrainzngs        # for metadata lookup
-    python2-pycdio                # for storing drive identification in config file
-    python2-requests
-    python2-setuptools            # for plugin support
-    sox                           # for track peak detection'
-    python2-ruamel.yaml           # for log output
-    )
-makedepends=(python2-setuptools-scm git)
-optdepends=(flac)
-checkdepends=(python2-twisted)
-conflicts=(morituri accuraterip-checksum)
-provides=(accuraterip-checksum)
-_tag=bf381b51f46735d1142c8b9c427cbd5b38ec31fd # git rev-parse v${pkgver}
-source=(git+${url}.git#tag=${_tag})
-sha512sums=(SKIP)
+  'cdrdao'                # for session, TOC, pregap, and ISRC extraction
+  'libcdio-paranoia'      # for the actual ripping
+  'libsndfile'            # for reading wav files (pulls in flac, also required for reading flac files)
+  'python-gobject'
+  'python-musicbrainzngs' # for metadata lookup
+  'python-mutagen'        # for metadata handling
+  'python-pycdio'         # for storing drive identification in config file
+  'python-requests'
+  'python-ruamel-yaml'    # for log output
+  'python-setuptools'     # for plugin support
+  'sox'                   # for track peak detection'
+)
+checkdepends=(
+  'python-twisted'
+)
+optdepends=('flac: For free lossless audio codec (FLAC) support')
+makedepends=('python-setuptools-scm')
+conflicts=('accuraterip-checksum')
+provides=('accuraterip-checksum')
+source=("${url}/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
+sha512sums=('49e66ad2c6e8450199a53a28bb71725704daac86ce2cbf68080d4dee1c2357cf8367ddb4735a07f2ffe612d84f016661e5b6f94efa9d5a7d6b8cf56ee32b0ae7')
 
 build() {
-    cd ${pkgname}
-    python2 setup.py build
+  cd "${pkgname}-${pkgver}"
+  echo "Version: ${pkgver}" > PKG-INFO
+  python setup.py build
 }
 
 check() {
-    cd ${pkgname}
-    # https://github.com/whipper-team/whipper/issues/420
-    sed -i 's|\\\.dev\[\\w\\\.\\+\]+|(\\.dev[\\w\\.+]+)?|' whipper/test/test_result_logger.py
-    # The accuraterip C extension needs to be in the python path
-    PYTHONPATH="build/lib.linux-${CARCH}-2.7/" python2 -m unittest discover
-    # https://github.com/whipper-team/whipper/issues/422
-    git checkout whipper/test/test_result_logger.py
+  cd "$srcdir/${pkgname}-${pkgver}"
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  PYTHONPATH="build/lib.linux-${CARCH}-${python_version}/" python -m unittest discover
 }
 
 package() {
-    cd ${pkgname}
-    python2 setup.py --version
-    python2 setup.py install --root="${pkgdir}"/ --optimize=1 --skip-build
+  cd "$srcdir/${pkgname}-${pkgver}"
+  python setup.py install --root="${pkgdir}"/ --optimize=1 --skip-build
 }