[arch-commits] Commit in aisleriot/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Sunday, December 8, 2019 @ 22:25:06
  Author: heftig
Revision: 370542

archrelease: copy trunk to extra-x86_64

Added:
  aisleriot/repos/extra-x86_64/PKGBUILD
    (from rev 370541, aisleriot/trunk/PKGBUILD)
Deleted:
  aisleriot/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |   95 +++++++++++++++++++++++++++----------------------------------
 1 file changed, 43 insertions(+), 52 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-12-08 22:24:56 UTC (rev 370541)
+++ PKGBUILD	2019-12-08 22:25:06 UTC (rev 370542)
@@ -1,52 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-
-pkgname=aisleriot
-pkgver=3.22.9
-pkgrel=1
-pkgdesc="A collection of patience games written in guile scheme"
-url="https://wiki.gnome.org/Apps/Aisleriot"
-arch=(x86_64)
-license=(GPL)
-depends=(guile gtk3 librsvg libcanberra dconf)
-makedepends=(appdata-tools gnome-common git)
-optdepends=('libkdegames: KDE card sets'
-            'pysolfc: PySol card sets'
-            'pysolfc-cardsets: PySol card sets')
-options=(!emptydirs)
-_commit=a2d1187bc052e599ef73ee640a28cbb2c4f23c2f  # tags/3.22.9^0
-source=("git+https://gitlab.gnome.org/GNOME/aisleriot.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd $pkgname
-
-  ./configure \
-    --prefix=/usr \
-    --sysconfdir=/etc \
-    --localstatedir=/var \
-    --libexecdir=/usr/lib \
-    --disable-static \
-    --with-platform=gtk-only \
-    --with-kde-card-theme-path=/usr/share/carddecks \
-    --with-pysol-card-theme-path=/usr/share/PySolFC
-
-  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-
-  make
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-}

Copied: aisleriot/repos/extra-x86_64/PKGBUILD (from rev 370541, aisleriot/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-12-08 22:25:06 UTC (rev 370542)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=aisleriot
+pkgver=3.22.10
+pkgrel=1
+pkgdesc="A collection of patience games written in guile scheme"
+url="https://wiki.gnome.org/Apps/Aisleriot"
+arch=(x86_64)
+license=(GPL)
+depends=(guile gtk3 librsvg libcanberra dconf)
+makedepends=(git meson yelp-tools appstream-glib)
+optdepends=('pysolfc: PySol card sets'
+            'pysolfc-cardsets: PySol card sets')
+_commit=5123a8c1bf87993ed5deef8ab13f5717496ba482  # tags/3.22.10^0
+source=("git+https://gitlab.gnome.org/GNOME/aisleriot.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D theme_kde=false \
+    -D theme_pysol=true \
+    -D theme_pysol_path=/usr/share/PySolFC
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}
+
+# vim:set sw=2 et: