[arch-commits] Commit in powerdns-recursor/repos (2 files)

[Antonio Rojas]

    Date: Tuesday, December 10, 2019 @ 21:45:24
  Author: arojas
Revision: 536585

archrelease: copy trunk to community-staging-x86_64

Added:
  powerdns-recursor/repos/community-staging-x86_64/
  powerdns-recursor/repos/community-staging-x86_64/PKGBUILD
    (from rev 536584, powerdns-recursor/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: powerdns-recursor/repos/community-staging-x86_64/PKGBUILD (from rev 536584, powerdns-recursor/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-10 21:45:24 UTC (rev 536585)
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Jan Steffens <heftig at archlinux.org>
+# Contributor: Remi Gacogne <rgacogne[at]archlinux[dot]org>
+
+pkgname=powerdns-recursor
+pkgver=4.2.0
+pkgrel=4
+pkgdesc='Resolving DNS server'
+url='https://www.powerdns.com/'
+arch=('x86_64')
+license=('GPL2')
+depends=('gcc-libs' 'boost-libs' 'libsodium' 'systemd-libs' 'lua' 'openssl' 'protobuf'
+         'libboost_context.so')
+makedepends=('boost' 'inetutils' 'pandoc' 'ragel' 'systemd')
+provides=('pdns-recursor')
+conflicts=('pdns-recursor')
+backup=('etc/powerdns/recursor.conf')
+source=(https://downloads.powerdns.com/releases/pdns-recursor-${pkgver}.tar.bz2{,.asc})
+sha512sums=('e4be63c1be70f0dfd7aab71f1184d5cc1d15e60e775451a96e8472db6fb3825762ebd6f51b593b167389868bbfde0538612b14a04c03f3f60a7e49f7882e78bf'
+            'SKIP')
+validpgpkeys=('B76CD4671C0968BAA87DE61C5E50715BF2FFE1A7'  # Pieter Lexis <pieter.lexis at powerdns.com>
+              'FBAE0323821C7706A5CA151BDCF513FA7EED19F3'  # Peter van Dijk <peter.van.dijk at powerdns.com>
+              '16E12866B7738C73976A57436FFC33439B0D04DF') # Winkels, Erik <erik.winkels at open-xchange.com>
+
+build() {
+  cd pdns-recursor-${pkgver}
+  ./configure \
+    --prefix=/usr \
+    --sbindir=/usr/bin \
+    --sysconfdir=/etc/powerdns \
+    --disable-silent-rules \
+    --enable-reproducible \
+    --enable-systemd \
+    --enable-protobuf \
+    --enable-libsodium
+  make
+}
+
+package() {
+  cd pdns-recursor-${pkgver}
+  make DESTDIR="${pkgdir}" install
+  mv "${pkgdir}/etc/powerdns/recursor.conf"{-dist,}
+}
+
+# vim: ts=2 sw=2 et: