[arch-commits] Commit in qt5-webglplugin/repos (2 files)

[Antonio Rojas]

    Date: Thursday, December 12, 2019 @ 09:46:05
  Author: arojas
Revision: 370748

archrelease: copy trunk to staging-x86_64

Added:
  qt5-webglplugin/repos/staging-x86_64/
  qt5-webglplugin/repos/staging-x86_64/PKGBUILD
    (from rev 370747, qt5-webglplugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: qt5-webglplugin/repos/staging-x86_64/PKGBUILD (from rev 370747, qt5-webglplugin/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-12-12 09:46:05 UTC (rev 370748)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=qt5-webglplugin
+_qtver=5.14.0
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='QPA plugin for running an application via a browser using streamed WebGL commands'
+depends=(qt5-websockets qt5-declarative)
+groups=(qt qt5)
+_pkgfqn="${pkgname/5-/}-everywhere-src-${_qtver}"
+source=("https://download.qt.io/official_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
+sha256sums=('9707f7b860d798d478c0237c49ab43d4b99e1ad5b297555a4df6ffac4c5a1a76')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+
+  qmake ../${_pkgfqn}
+  make
+}
+
+package() {
+  cd build
+  make INSTALL_ROOT="$pkgdir" install
+
+  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
+  find "$pkgdir/usr/lib" -type f -name '*.prl' \
+    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
+}