[arch-commits] Commit in zam-plugins/repos/community-x86_64 (4 files)

David Runge dvzrv at archlinux.org
Sun Dec 15 13:35:19 UTC 2019


    Date: Sunday, December 15, 2019 @ 13:35:19
  Author: dvzrv
Revision: 537738

archrelease: copy trunk to community-x86_64

Added:
  zam-plugins/repos/community-x86_64/PKGBUILD
    (from rev 537737, zam-plugins/trunk/PKGBUILD)
  zam-plugins/repos/community-x86_64/zam-plugins.directory
    (from rev 537737, zam-plugins/trunk/zam-plugins.directory)
  zam-plugins/repos/community-x86_64/zam-plugins.menu
    (from rev 537737, zam-plugins/trunk/zam-plugins.menu)
Deleted:
  zam-plugins/repos/community-x86_64/PKGBUILD

-----------------------+
 PKGBUILD              |  153 ++++++++++++++++++++++++++++++++++++------------
 zam-plugins.directory |    4 +
 zam-plugins.menu      |   14 ++++
 3 files changed, 135 insertions(+), 36 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-12-15 13:35:12 UTC (rev 537737)
+++ PKGBUILD	2019-12-15 13:35:19 UTC (rev 537738)
@@ -1,36 +0,0 @@
-# Maintainer: David Runge <dave at sleepmap.de>
-pkgname=zam-plugins
-pkgver=3.11
-pkgrel=1
-pkgdesc="Collection of LADSPA/LV2/VST/JACK audio plugins for high-quality processing"
-arch=('x86_64')
-url="https://github.com/zamaudio/zam-plugins"
-license=('GPL2')
-groups=('ladspa-plugins' 'lv2-plugins' 'pro-audio' 'vst-plugins')
-depends=('jack' 'libglvnd' 'liblo' 'zita-convolver')
-makedepends=('git' 'ladspa' 'libx11' 'libgl' 'lv2')
-source=("$pkgname-$pkgver::git+https://github.com/zamaudio/${pkgname}.git#tag=${pkgver}"
-        "git+https://github.com/distrho/dpf.git")
-sha512sums=('SKIP'
-            'SKIP')
-
-prepare() {
-  cd "$pkgname-$pkgver"
-  git submodule init
-  git config submodule.dpf.url "${srcdir}/dpf"
-  git submodule update
-}
-
-build() {
-  cd "$pkgname-$pkgver"
-  export HAVE_ZITA_CONVOLVER=true
-  make
-}
-
-package() {
-  cd "$pkgname-$pkgver"
-  make DESTDIR="$pkgdir/" PREFIX='/usr' install
-  # docs
-  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
-    -vDm 644 {README.md,changelog}
-}

Copied: zam-plugins/repos/community-x86_64/PKGBUILD (from rev 537737, zam-plugins/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-12-15 13:35:19 UTC (rev 537738)
@@ -0,0 +1,117 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+pkgname=zam-plugins
+pkgver=3.12
+pkgrel=1
+pkgdesc="Collection of LADSPA/LV2/VST/JACK audio plugins for high-quality processing"
+arch=('x86_64')
+url="https://github.com/zamaudio/zam-plugins"
+license=('GPL2')
+groups=('ladspa-plugins' 'lv2-plugins' 'pro-audio' 'vst-plugins')
+depends=('gcc-libs' 'glibc' 'libglvnd' 'libsamplerate' 'libx11' 'libzita-convolver.so')
+makedepends=('gendesk' 'git' 'ladspa' 'libjack.so' 'lv2')
+optdepends=('libjack.so: for standalone applications')
+source=("$pkgname-$pkgver::git+https://github.com/zamaudio/${pkgname}.git#tag=${pkgver}"
+        "git+https://github.com/distrho/dpf.git"
+        "${pkgname}.directory"
+        "${pkgname}.menu")
+sha512sums=('SKIP'
+            'SKIP'
+            'a2b07759c32598222dac81e472fd7b30070e36d416ec5f0f7c88dc21e6bbaab2664bd1883ffb8e902714521f89eacf0b8416146a6f45bf1a0bf30f957e900c9b'
+            'f92c22af4ec532944e39850a48b6b0bae072a57833bb82d63b606836b92b118d4b2d8704d82814cbff4cc2f16bc87f475a32a3f16a8f001617209b474df0104d')
+_names=('zamaximx2' 'zamulticomp' 'zammulticompx2' 'zamautosat' 'zamcomp'
+'zamcompx2' 'zamdelay' 'zamdynamiceq' 'zameq2' 'zamgeq31' 'zamgate' 'zamgatex2'
+'zamgrains' 'zamheadx2' 'zamphono' 'zamtube' 'zamverb')
+
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  git submodule init
+  git config submodule.dpf.url "${srcdir}/dpf"
+  git submodule update
+  declare -A exec_names=(
+    ["zamaximx2"]="ZaMaximX2"
+    ["zamulticomp"]="ZaMultiComp"
+    ["zamulticompx2"]="ZaMultiCompX2"
+    ["zamautosat"]="ZamAutoSat"
+    ["zamcomp"]="ZamComp"
+    ["zamcompx2"]="ZamCompX2"
+    ["zamdelay"]="ZamDelay"
+    ["zamdynamiceq"]="ZamDynamicEQ"
+    ["zameq2"]="ZamEQ2"
+    ["zamgeq31"]="ZamGEQ31"
+    ["zamgate"]="ZamGate"
+    ["zamgatex2"]="ZamGateX2"
+    ["zamgrains"]="ZamGrains"
+    ["zamheadx2"]="ZamHeadX2"
+    ["zamphono"]="ZamPhono"
+    ["zamtube"]="ZamTube"
+    ["zamverb"]="ZamVerb"
+  )
+  declare -A comments=(
+    ["zamaximx2"]="Acts as a brickwall limiter for mastering in its default state, but can also be tweaked to raise the average level as a stereo maximizer without ever clipping"
+    ["zamulticomp"]="Mono multiband compressor, with 3 adjustable bands."
+    ["zamulticompx2"]="Stereo version of ZaMultiComp, with individual threshold controls for each band and real-time visualisation of comp curves."
+    ["zamautosat"]="An automatic saturation plugin, has been known to provide smooth levelling to live mic channels."
+    ["zamcomp"]="A powerful mono compressor strip"
+    ["zamcompx2"]="Stereo version of ZamComp with knee slew control"
+    ["zamdelay"]="A simple feedback delay unit with sync-to-host BPM feature and filter."
+    ["zamdynamiceq"]="A dynamic equalizer that changes its gain based on detecting a narrow band of frequencies."
+    ["zameq2"]="Two band parametric equaliser with high and low shelving circuits."
+    ["zamgeq31"]="31 band graphic equaliser, good for eq of live spaces, removing unwanted noise from a track etc."
+    ["zamgate"]="Gate plugin for ducking low gain sounds."
+    ["zamgatex2"]="Gate plugin for ducking low gain sounds, stereo version."
+    ["zamgrains"]="Granular Synthesizer"
+    ["zamheadx2"]="HRTF acoustic filtering plugin for directional sound."
+    ["zamphono"]="A collection of phono filters for restoring vinyl records, or preparing to cut new ones."
+    ["zamtube"]="Wave digital filter physical model of a triode tube amplifier stage, with modelled tone stacks from real guitar amplifiers"
+    ["zamverb"]="Reverb"
+  )
+  declare -A generic=(
+    ["zamaximx2"]="Maximizer and brickwall limiter"
+    ["zamulticomp"]="Mono Multiband Compressor"
+    ["zamulticompx2"]="Stereo Multiband Compressor"
+    ["zamautosat"]="Automatic Saturation"
+    ["zamcomp"]="Mono Compressor"
+    ["zamcompx2"]="Stereo Compressor"
+    ["zamdelay"]="Delay"
+    ["zamdynamiceq"]="Dynamic Equalizer"
+    ["zameq2"]="2 Band Parametric Equalizer"
+    ["zamgeq31"]="31 Band Graphic Equalizer"
+    ["zamgate"]="Mono Gate"
+    ["zamgatex2"]="Stereo Gate"
+    ["zamgrains"]="Granular Synthesizer"
+    ["zamheadx2"]="HRTF Acoustic Filtering"
+    ["zamphono"]="Phono Filters"
+    ["zamtube"]="Tube Amplifier"
+    ["zamverb"]="Reverb"
+  )
+  for name in "${_names[@]}"; do
+    gendesk -n \
+            --pkgname "com.zamaudio.${name}" \
+            --name "${name}" \
+            --exec "${exec_names[$name]}" \
+            --pkgdesc "${comments[$name]}" \
+            --genericname "${generic[$name]}" \
+            --categories "zam-plugins"
+  done
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  export HAVE_ZITA_CONVOLVER=true
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  make DESTDIR="$pkgdir/" PREFIX='/usr' install
+  # XDG desktop integration
+  install -vDm 644 *.desktop -t "${pkgdir}/usr/share/applications"
+  install -vDm 644 "../${pkgname}.menu" \
+    -t "${pkgdir}/etc/xdg/menus/applications-merged/"
+  install -vDm 644 "../${pkgname}.directory" \
+    -t "${pkgdir}/usr/share/desktop-directories/"
+  # docs
+  install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
+    -vDm 644 {README.md,changelog}
+}

Copied: zam-plugins/repos/community-x86_64/zam-plugins.directory (from rev 537737, zam-plugins/trunk/zam-plugins.directory)
===================================================================
--- zam-plugins.directory	                        (rev 0)
+++ zam-plugins.directory	2019-12-15 13:35:19 UTC (rev 537738)
@@ -0,0 +1,4 @@
+[Desktop Entry]
+Name=zam-plugins
+Icon=zam-plugins
+Type=Directory

Copied: zam-plugins/repos/community-x86_64/zam-plugins.menu (from rev 537737, zam-plugins/trunk/zam-plugins.menu)
===================================================================
--- zam-plugins.menu	                        (rev 0)
+++ zam-plugins.menu	2019-12-15 13:35:19 UTC (rev 537738)
@@ -0,0 +1,14 @@
+<!DOCTYPE Menu PUBLIC "-//freedesktop//DTD Menu 1.0//EN" "http://www.freedesktop.org/standards/menu-spec/menu-1.0.dtd">
+<Menu>
+  <Name>Applications</Name>
+  <Menu>
+    <Name>Multimedia</Name>
+    <Menu>
+      <Name>zam-plugins</Name>
+      <Directory>zam-plugins.directory</Directory>
+      <Include>
+         <Category>zam-plugins</Category>
+      </Include>
+    </Menu>
+  </Menu>
+</Menu>


More information about the arch-commits mailing list