[arch-commits] Commit in nvidia-lts/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Jan Steffens heftig at archlinux.org
Wed Dec 18 00:20:08 UTC 2019


    Date: Wednesday, December 18, 2019 @ 00:20:08
  Author: heftig
Revision: 371623

archrelease: copy trunk to testing-x86_64

Added:
  nvidia-lts/repos/testing-x86_64/
  nvidia-lts/repos/testing-x86_64/PKGBUILD
    (from rev 371621, nvidia-lts/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: nvidia-lts/repos/testing-x86_64/PKGBUILD (from rev 371621, nvidia-lts/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2019-12-18 00:20:08 UTC (rev 371623)
@@ -0,0 +1,42 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgname=nvidia-lts
+pkgver=440.44
+pkgrel=3
+epoch=1
+pkgdesc="NVIDIA drivers for linux-lts"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=("nvidia-utils=${pkgver}" 'libglvnd' 'linux-lts-headers')
+provides=('nvidia')
+license=('custom')
+options=('!strip')
+_pkg="NVIDIA-Linux-x86_64-${pkgver}"
+source=("https://us.download.nvidia.com/XFree86/Linux-x86_64/${pkgver}/${_pkg}.run")
+sha512sums=('c0c0e19cdb82d47575adbcf46e23580977cf7a5097edfb9d76464c2e678a44f556d8c2d0d49515a86b6765f57176460193c6951927e24c278e6a7f411f89f26b')
+
+prepare() {
+    sh "${_pkg}.run" --extract-only
+    cd "${_pkg}"
+}
+
+build() {
+    cd "${_pkg}"/kernel
+    make SYSSRC=/usr/src/linux-lts module
+}
+
+package() {
+    depends=('linux-lts' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _extradir="/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules"
+    install -Dt "${pkgdir}${_extradir}" -m644 \
+      "${srcdir}/${_pkg}/kernel"/nvidia{,-modeset,-drm,-uvm}.ko
+
+    find "${pkgdir}" -name '*.ko' -exec gzip -n {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 "${srcdir}/${_pkg}/LICENSE"
+}



More information about the arch-commits mailing list