[arch-commits] Commit in x264/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Maxime Gauduin]

    Date: Thursday, December 19, 2019 @ 20:51:54
  Author: alucryd
Revision: 371941

archrelease: copy trunk to staging-x86_64

Added:
  x264/repos/staging-x86_64/
  x264/repos/staging-x86_64/PKGBUILD
    (from rev 371940, x264/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: x264/repos/staging-x86_64/PKGBUILD (from rev 371940, x264/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-12-19 20:51:54 UTC (rev 371941)
@@ -0,0 +1,62 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Paul Mattal <paul at archlinux.org>
+
+pkgname=x264
+pkgver=0.159.r2991.1771b55
+pkgrel=1
+epoch=3
+pkgdesc='Open Source H264/AVC video encoder'
+arch=(x86_64)
+url=https://www.videolan.org/developers/x264.html
+license=(GPL)
+depends=(
+  liblsmash.so
+)
+makedepends=(
+  git
+  l-smash
+  nasm
+)
+provides=(
+  libx264
+  libx264.so
+)
+conflicts=(
+  libx264
+  libx264-10bit
+  libx264-all
+)
+replaces=(
+  libx264
+  libx264-10bit
+  libx264-all
+)
+source=(git+https://code.videolan.org/videolan/x264.git#commit=1771b556ee45207f8711744ccbd5d42a3949b14c)
+sha256sums=(SKIP)
+
+pkgver() {
+  cd x264
+
+  ./version.sh | grep X264_POINTVER | sed -r 's/^#define X264_POINTVER "([0-9]+\.[0-9]+)\.([0-9]+) (.*)"$/\1.r\2.\3/'
+}
+
+build() {
+  cd x264
+
+  ./configure \
+    --prefix=/usr \
+    --enable-shared \
+    --enable-pic \
+    --enable-lto \
+    --disable-avs
+  make
+}
+
+package() {
+  make -C x264 DESTDIR="${pkgdir}" install-cli install-lib-shared
+}
+
+# vim: ts=2 sw=2 et: