[arch-commits] Commit in opencv/repos (3 files)

[Antonio Rojas]

    Date: Saturday, December 21, 2019 @ 00:28:03
  Author: arojas
Revision: 372008

archrelease: copy trunk to staging-x86_64

Added:
  opencv/repos/staging-x86_64/
  opencv/repos/staging-x86_64/PKGBUILD
    (from rev 372007, opencv/trunk/PKGBUILD)
  opencv/repos/staging-x86_64/opencv-includedir.patch
    (from rev 372007, opencv/trunk/opencv-includedir.patch)

-------------------------+
 PKGBUILD                |   94 ++++++++++++++++++++++++++++++++++++++++++++++
 opencv-includedir.patch |    9 ++++
 2 files changed, 103 insertions(+)

Copied: opencv/repos/staging-x86_64/PKGBUILD (from rev 372007, opencv/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-12-21 00:28:03 UTC (rev 372008)
@@ -0,0 +1,94 @@
+# Maintainer: Ray Rashif <schiv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgbase=opencv
+pkgname=(opencv opencv-samples)
+pkgver=4.2.0
+pkgrel=1
+pkgdesc="Open Source Computer Vision Library"
+arch=(x86_64)
+license=(BSD)
+url="https://opencv.org/"
+depends=(intel-tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 jasper ffmpeg)
+makedepends=(cmake python-numpy python-setuptools mesa eigen hdf5 lapacke qt5-base vtk glew ant java-environment xorgproto)
+optdepends=('opencv-samples: samples'
+            'vtk: for the viz module'
+            'qt5-base: for the HighGUI module and the Python bindings'
+            'hdf5: for the HDF5 module and the Python bindings'
+            'opencl-icd-loader: For coding with OpenCL'
+            'python-numpy: Python bindings'
+            'java-runtime: Java interface')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/opencv/opencv/archive/$pkgver.zip"
+        "opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz"
+        opencv-includedir.patch)
+sha256sums=('55bd939079d141a50fca74bde5b61b339dd0f0ece6320ec76859aaff03c90d9f'
+            '8a6b5661611d89baa59a26eb7ccf4abb3e55d73f99bb52d8f7c32265c8a43020'
+            'a96e35c9592e655b21a62cfe04e864a10e21535ad900e5de67356b9e9f40ca10')
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgname-$pkgver
+  patch -p1 -i ../opencv-includedir.patch # Fix wrong include patch in pkgconfig file
+
+  sed -e '/ocv_tbb_cmake_guess(HAVE_TBB)/d' -i cmake/OpenCVDetectTBB.cmake # Don't use TBB's cmake config, it breaks build
+}
+
+build() {
+  cd build
+  export JAVA_HOME="/usr/lib/jvm/default"
+  # cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  cmake ../$pkgname-$pkgver \
+    -DWITH_OPENCL=ON \
+    -DWITH_OPENGL=ON \
+    -DWITH_TBB=ON \
+    -DWITH_QT=ON \
+    -DBUILD_WITH_DEBUG_INFO=OFF \
+    -DBUILD_TESTS=OFF \
+    -DBUILD_PERF_TESTS=OFF \
+    -DBUILD_EXAMPLES=ON \
+    -DINSTALL_C_EXAMPLES=ON \
+    -DINSTALL_PYTHON_EXAMPLES=ON \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCPU_BASELINE_DISABLE=SSE3 \
+    -DCPU_BASELINE_REQUIRE=SSE2 \
+    -DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
+    -DOPENCV_SKIP_PYTHON_LOADER=ON \
+    -DOPENCV_PYTHON3_INSTALL_PATH=$_pythonpath \
+    -DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
+    -DLAPACK_CBLAS_H="/usr/include/cblas.h" \
+    -DLAPACK_LAPACKE_H="/usr/include/lapacke.h" \
+    -DOPENCV_GENERATE_PKGCONFIG=ON \
+    -DOPENCV_ENABLE_NONFREE=ON \
+    -DOPENCV_JNI_INSTALL_PATH=lib \
+    -DOPENCV_GENERATE_SETUPVARS=OFF \
+    -DEIGEN_INCLUDE_PATH=/usr/include/eigen3
+  make
+}
+
+package_opencv() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # install license file
+  install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+
+  # separate samples package
+  cd "$pkgdir"/usr/share
+  mv opencv4/samples "$srcdir"/$pkgname-samples
+}
+
+package_opencv-samples() {
+  pkgdesc+=" (samples)"
+  depends=("opencv=$pkgver")
+  unset optdepends
+
+  mkdir -p "$pkgdir"/usr/share/opencv
+  cp -r "$srcdir"/opencv-samples "$pkgdir"/usr/share/opencv/samples
+  # fix permissions
+  chmod 755 "$pkgdir"/usr/share/opencv/samples/*
+
+  # install license file
+  install -Dm644 "$srcdir"/opencv-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}

Copied: opencv/repos/staging-x86_64/opencv-includedir.patch (from rev 372007, opencv/trunk/opencv-includedir.patch)
===================================================================
--- staging-x86_64/opencv-includedir.patch	                        (rev 0)
+++ staging-x86_64/opencv-includedir.patch	2019-12-21 00:28:03 UTC (rev 372008)
@@ -0,0 +1,9 @@
+diff -u -r opencv-4.0.1/cmake/templates/opencv-XXX.pc.in opencv-4.0.1-includedir/cmake/templates/opencv-XXX.pc.in
+--- opencv-4.0.1/cmake/templates/opencv-XXX.pc.in	2018-12-22 07:03:30.000000000 +0000
++++ opencv-4.0.1-includedir/cmake/templates/opencv-XXX.pc.in	2019-02-07 15:08:15.016613349 +0000
+@@ -11,4 +10,4 @@
+ Version: @OPENCV_VERSION_PLAIN@
+ Libs: @OPENCV_PC_LIBS@
+ Libs.private: @OPENCV_PC_LIBS_PRIVATE@
+-Cflags: -I${includedir_old} -I${includedir_new}
++Cflags: -I${includedir_new}