[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Mon Dec 23 12:01:21 UTC 2019


    Date: Monday, December 23, 2019 @ 12:01:20
  Author: felixonmars
Revision: 539106

add old pytest for python2

Added:
  python2-pytest/
  python2-pytest/repos/
  python2-pytest/trunk/
  python2-pytest/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python2-pytest/trunk/PKGBUILD
===================================================================
--- python2-pytest/trunk/PKGBUILD	                        (rev 0)
+++ python2-pytest/trunk/PKGBUILD	2019-12-23 12:01:20 UTC (rev 539106)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Felix Kaiser <felix.kaiser at fxkr.net>
+
+pkgname=python2-pytest
+pkgver=4.6.8
+pkgrel=1
+pkgdesc="Simple powerful testing with Python"
+arch=('any')
+license=('MIT')
+url="https://pytest.org/"
+depends=('python2-py' 'python2-setuptools' 'python2-pluggy' 'python2-attrs' 'python2-more-itertools'
+         'python2-atomicwrites' 'python2-wcwidth' 'python2-funcsigs' 'python2-pathlib2'
+         'python2-importlib-metadata')
+makedepends=('python2-setuptools-scm')
+checkdepends=('lsof' 'python2-nose' 'python2-mock' 'python2-requests' 'python2-hypothesis'
+              # Unlisted, but actually used. Check again after a while:
+              'python2-numpy' 'python2-twisted' 'python2-pytest-xdist' 'python2-decorator'
+              'python2-jinja' 'python2-pexpect')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/pytest-dev/pytest/archive/$pkgver.tar.gz")
+sha512sums=('b6280ba1dec3f49bb54639d87e22936f655b2e67829e658715e151d70916b826b19cbc43812c17ead748e7927d5aab0b28f1a3a1059548400c71cd3830956230')
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+prepare() {
+  # Ignore warnings that break test
+  # sed -e 's|2 passed in|2 passed|' -i pytest-$pkgver/testing/test_pdb.py
+  :
+}
+
+build() {
+  cd pytest-$pkgver
+  python2 setup.py build
+}
+
+check() {
+  # Skip test_collect_pyargs_with_testpaths because it mangles PYTHONPATH
+
+  cd pytest-$pkgver
+  python2 setup.py egg_info
+  PYTHONPATH="$PWD"/build/lib python2 src/pytest.py -k 'not test_collect_pyargs_with_testpaths'
+}
+
+package() {
+  cd pytest-$pkgver
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  mv "$pkgdir"/usr/bin/py.test{,2}
+  mv "$pkgdir"/usr/bin/pytest{,2}
+}


More information about the arch-commits mailing list