[arch-commits] Commit in haskell-profunctors/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 25, 2019 @ 10:13:01
  Author: felixonmars
Revision: 540709

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-profunctors/repos/community-staging-x86_64/
  haskell-profunctors/repos/community-staging-x86_64/PKGBUILD
    (from rev 540708, haskell-profunctors/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-profunctors/repos/community-staging-x86_64/PKGBUILD (from rev 540708, haskell-profunctors/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-25 10:13:01 UTC (rev 540709)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=profunctors
+pkgname=haskell-profunctors
+pkgver=5.5.1
+pkgrel=3
+pkgdesc="Profunctors"
+url="https://github.com/ekmett/profunctors/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-orphans' 'haskell-bifunctors' 'haskell-comonad'
+         'haskell-contravariant' 'haskell-distributive' 'haskell-tagged')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('6f2b3cfe7ab629dd224319eef020bf92068a0b6b66019ab11dacb0e3540a2581605849037a9f2c0e1bca4330a4bce63266c9378cdb1bd612cdce52e7dae53481')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}