[arch-commits] Commit in haskell-rebase/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 25, 2019 @ 15:01:46
  Author: felixonmars
Revision: 541172

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-rebase/repos/community-staging-x86_64/
  haskell-rebase/repos/community-staging-x86_64/PKGBUILD
    (from rev 541171, haskell-rebase/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-rebase/repos/community-staging-x86_64/PKGBUILD (from rev 541171, haskell-rebase/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-25 15:01:46 UTC (rev 541172)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=rebase
+pkgname=haskell-rebase
+pkgver=1.4.1
+pkgrel=7
+pkgdesc='A more progressive alternative to the "base" package'
+url="https://github.com/nikita-volkov/rebase"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-prelude' 'haskell-bifunctors' 'haskell-contravariant'
+         'haskell-contravariant-extras' 'haskell-comonad' 'haskell-dlist' 'haskell-either'
+         'haskell-hashable' 'haskell-profunctors' 'haskell-scientific' 'haskell-selective'
+         'haskell-semigroupoids' 'haskell-unordered-containers' 'haskell-uuid' 'haskell-vector'
+         'haskell-void')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('70bb6513e6ea6a1cd3adf077fe454cf4f1a3b220224fc76e3d63050f17c22cc2d218efa8803f269a3605cb0b95e7ea11b3e8b55ec80cd7fb2db4dbf330739a18')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -e '/fail/d' -e '/semigroups/d' -i $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}