[arch-commits] Commit in ruby-minitest/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Wed Dec 25 22:43:55 UTC 2019


    Date: Wednesday, December 25, 2019 @ 22:43:54
  Author: foutrelis
Revision: 541357

archrelease: copy trunk to community-staging-any

Added:
  ruby-minitest/repos/community-staging-any/
  ruby-minitest/repos/community-staging-any/PKGBUILD
    (from rev 541356, ruby-minitest/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: ruby-minitest/repos/community-staging-any/PKGBUILD (from rev 541356, ruby-minitest/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2019-12-25 22:43:54 UTC (rev 541357)
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Simon Kohlmeyer <simon.kohlmeyer at gmail.com>
+
+_gemname=minitest
+pkgname=ruby-${_gemname}
+_gitcommit=ecb1afeb36f831d20f1f0f9081bd1b8e32ddbdfe
+pkgver=5.13.0
+pkgrel=2
+pkgdesc='Complete suite of testing facilities supporting TDD, BDD, mocking, and benchmarking'
+url='https://github.com/seattlerb/minitest'
+arch=('any')
+license=('MIT')
+depends=('ruby')
+makedepends=('git' 'rubygems' 'ruby-rake' 'ruby-rdoc' 'ruby-hoe')
+options=('!emptydirs')
+source=("git+https://github.com/seattlerb/minitest#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${_gemname}
+  grep 'VERSION = "' lib/minitest.rb|sed -E 's|.*"(.+)".*|\1|'
+}
+
+build() {
+  cd ${_gemname}
+  rake gem
+}
+
+check() {
+  cd ${_gemname}
+  rake test
+}
+
+package() {
+  cd ${_gemname}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
+    -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
+  install -Dm 644 README.rdoc History.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm -r "${pkgdir}/${_gemdir}/cache"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list