[arch-commits] Commit in ruby-nio4r/repos (2 files)

[Felix Yan]

    Date: Thursday, December 26, 2019 @ 00:23:48
  Author: felixonmars
Revision: 541574

archrelease: copy trunk to community-staging-x86_64

Added:
  ruby-nio4r/repos/community-staging-x86_64/
  ruby-nio4r/repos/community-staging-x86_64/PKGBUILD
    (from rev 541572, ruby-nio4r/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: ruby-nio4r/repos/community-staging-x86_64/PKGBUILD (from rev 541572, ruby-nio4r/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-26 00:23:48 UTC (rev 541574)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+_gemname=nio4r
+pkgname=ruby-${_gemname}
+pkgver=2.5.2
+pkgrel=2
+pkgdesc='Abstract, cross-platform stateful I/O selector API for Ruby'
+url='https://github.com/celluloid/nio4r'
+arch=('x86_64')
+license=('MIT')
+depends=('ruby')
+makedepends=('ruby-rdoc')
+options=('!emptydirs')
+source=(https://github.com/celluloid/nio4r/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('f8a3e12f51c2ee01644f5ebb5e33795be8ece6dd9345bf5fc1ab6d0a72f5118b')
+sha512sums=('4188be15b674e65373c056bdf86ee7dc71ebbabf1e0a3eb5a10edfbe0dfe761c5cba6e89c4a0fc822037901c7e83831c26682770129e023ab9223a6467b9e83c')
+
+prepare() {
+  cd ${_gemname}-${pkgver}
+  sed 's|git ls-files|find|' -i ${_gemname}.gemspec
+}
+
+build() {
+  cd ${_gemname}-${pkgver}
+  gem build ${_gemname}.gemspec
+}
+
+package() {
+  cd ${_gemname}-${pkgver}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
+    -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
+
+  install -Dm 644 README.md CHANGES.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  cp -r examples "${pkgdir}/usr/share/doc/${pkgname}"
+
+  cd "${pkgdir}/${_gemdir}"
+  rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
+    extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
+}
+
+# vim: ts=2 sw=2 et: