[arch-commits] Commit in weechat/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Dec 26 01:34:27 UTC 2019


    Date: Thursday, December 26, 2019 @ 01:34:27
  Author: felixonmars
Revision: 541789

archrelease: copy trunk to community-staging-x86_64

Added:
  weechat/repos/community-staging-x86_64/
  weechat/repos/community-staging-x86_64/PKGBUILD
    (from rev 541788, weechat/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: weechat/repos/community-staging-x86_64/PKGBUILD (from rev 541788, weechat/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2019-12-26 01:34:27 UTC (rev 541789)
@@ -0,0 +1,43 @@
+# Maintainer : Christian Rebischke <Chris.Rebischke at archlinux.org>
+# Maintainer : Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: lucke <lucke at o2 dot pl>
+
+pkgname=weechat
+pkgver=2.7
+pkgrel=2
+pkgdesc="Fast, light and extensible IRC client (curses UI)"
+arch=('x86_64')
+url="https://www.weechat.org/"
+license=('GPL')
+depends=('gnutls' 'curl' 'libgcrypt')
+makedepends=('asciidoctor' 'cmake' 'aspell' 'guile2.0' 'lua' 'perl' 'python'
+             'ruby' 'tcl')
+optdepends=('aspell: spellchecker support'
+            'guile2.0: support for guile scripts'
+            'lua: support for lua scripts'
+            'perl: support for perl scripts'
+            'python: support for python scripts'
+            'ruby: support for ruby scripts'
+            'tcl: support for tcl scripts')
+source=("https://www.weechat.org/files/src/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha512sums=('5377cf9c37520cb2b7d1ba43251df3f33d814783ea4bd20d28cb08a2106c8db0e44a392a61929987b807a7d5e69a3c0ed1f3fec122a014b7ea7068e159341075'
+            'SKIP')
+validpgpkeys=('A9AB5AB778FA5C3522FD0378F82F4B16DEC408F8') # WeeChat (signing key) <webmaster at weechat.org>
+
+build() {
+  mkdir -p build
+  cd build
+  cmake -Wno-dev "${srcdir}/${pkgname}-${pkgver}" \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DENABLE_MAN=ON \
+        -DENABLE_DOC=ON \
+        -DENABLE_JAVASCRIPT=OFF \
+        -DENABLE_PHP=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="${pkgdir}" install
+}



More information about the arch-commits mailing list