[arch-commits] Commit in python-mako/repos (testing-any testing-any/PKGBUILD)

[Felix Yan]

    Date: Thursday, December 26, 2019 @ 15:00:34
  Author: felixonmars
Revision: 372311

archrelease: copy trunk to testing-any

Added:
  python-mako/repos/testing-any/
  python-mako/repos/testing-any/PKGBUILD
    (from rev 372310, python-mako/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-mako/repos/testing-any/PKGBUILD (from rev 372310, python-mako/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2019-12-26 15:00:34 UTC (rev 372311)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-mako
+pkgname=('python-mako' 'python2-mako')
+pkgver=1.1.0
+pkgrel=1
+pkgdesc="A super-fast templating language that borrows the best ideas from the existing templating languages"
+arch=('any')
+url="https://www.makotemplates.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-markupsafe' 'python2-markupsafe'
+             'python-beaker' 'python2-beaker')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-mock' 'python2-mock'
+              'python-babel' 'python2-babel' 'python-pygments' 'python2-pygments'
+              'python-dogpile.cache' 'python2-dogpile.cache')
+source=("https://pypi.io/packages/source/M/Mako/Mako-$pkgver.tar.gz"{,.asc})
+sha512sums=('acb0f53a22ae152c359c38391f508eca706efcc52916a6e87f2702517dd48b5ffd26eef0f2f9172046f1abd0aea1f47328354ff622938886aa00f950a261e8d4'
+            'SKIP')
+validpgpkeys=('83AF7ACE251C13E6BB7DEFBD330239C1C4DAFEE1')  # Michael Bayer
+
+prepare() {
+  cp -a Mako-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/Mako-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/Mako-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/Mako-$pkgver
+  python setup.py ptr
+
+  cd "$srcdir"/Mako-$pkgver-py2
+  python2 setup.py ptr
+}
+
+package_python-mako() {
+  depends=('python-markupsafe' 'python-beaker' 'python-setuptools')
+
+  cd Mako-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mako() {
+  depends=('python2-markupsafe' 'python2-beaker' 'python2-setuptools')
+
+  cd Mako-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  mv "$pkgdir"/usr/bin/mako-render{,2}
+}