[arch-commits] Commit in libva/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Maxime Gauduin]

    Date: Monday, December 30, 2019 @ 02:40:36
  Author: alucryd
Revision: 372374

archrelease: copy trunk to extra-x86_64

Added:
  libva/repos/extra-x86_64/PKGBUILD
    (from rev 372373, libva/trunk/PKGBUILD)
Deleted:
  libva/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  118 ++++++++++++++++++++++++++++++++-----------------------------
 1 file changed, 62 insertions(+), 56 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2019-12-30 02:40:31 UTC (rev 372373)
+++ PKGBUILD	2019-12-30 02:40:36 UTC (rev 372374)
@@ -1,56 +0,0 @@
-# Maintainer: Maxime Gauduin <alucryd at archlonux.org>
-# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
-# Contributor: Ionut Biru <ibiru at archlinux.org>
-
-pkgname=libva
-pkgver=2.5.0
-pkgrel=1
-pkgdesc='Video Acceleration (VA) API for Linux'
-arch=(x86_64)
-url=https://01.org/linuxmedia/vaapi
-license=(MIT)
-depends=(
-  libdrm
-  libgl
-  libx11
-  libxext
-  libxfixes
-  wayland
-)
-makedepends=(
-  git
-  libglvnd
-  mesa
-  meson
-)
-optdepends=(
-  'libva-vdpau-driver: backend for Nvidia and AMD cards'
-  'libva-intel-driver: backend for Intel cards'
-)
-provides=(
-  libva-drm.so
-  libva-glx.so
-  libva-wayland.so
-  libva-x11.so
-  libva.so
-)
-backup=(etc/libva.conf)
-source=(git+https://github.com/intel/libva.git#tag=${pkgver})
-sha256sums=('SKIP')
-
-build() {
-  CFLAGS+=" -DENABLE_VA_MESSAGING"  # Option missing
-  arch-meson libva build
-  ninja -C build
-}
-
-package() {
-  DESTDIR="${pkgdir}" meson install -C build
-  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/libva
-
-  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
-LIBVA_MESSAGING_LEVEL=1
-END
-}
-
-# vim: ts=2 sw=2 et:

Copied: libva/repos/extra-x86_64/PKGBUILD (from rev 372373, libva/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-12-30 02:40:36 UTC (rev 372374)
@@ -0,0 +1,62 @@
+# Maintainer: Maxime Gauduin <alucryd at archlonux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=libva
+pkgver=2.6.0
+pkgrel=1
+pkgdesc='Video Acceleration (VA) API for Linux'
+arch=(x86_64)
+url=https://01.org/linuxmedia/vaapi
+license=(MIT)
+depends=(
+  libdrm
+  libgl
+  libx11
+  libxext
+  libxfixes
+  wayland
+)
+makedepends=(
+  git
+  libglvnd
+  mesa
+  meson
+)
+optdepends=(
+  'libva-vdpau-driver: backend for Nvidia and AMD cards'
+  'libva-intel-driver: backend for Intel cards'
+)
+provides=(
+  libva-drm.so
+  libva-glx.so
+  libva-wayland.so
+  libva-x11.so
+  libva.so
+)
+backup=(etc/libva.conf)
+source=(git+https://github.com/intel/libva.git#tag=5f693d9e603e0e83928cec67c30b6ac902d7aa85)
+sha256sums=(SKIP)
+
+pkgver() {
+  cd libva
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS+=" -DENABLE_VA_MESSAGING"  # Option missing
+  arch-meson libva build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/libva
+
+  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
+LIBVA_MESSAGING_LEVEL=1
+END
+}
+
+# vim: ts=2 sw=2 et: