[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Sunday, February 3, 2019 @ 16:46:04
  Author: anthraxx
Revision: 429490

addpkg: ruby-hoe 3.17.1-1

Added:
  ruby-hoe/
  ruby-hoe/repos/
  ruby-hoe/trunk/
  ruby-hoe/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: ruby-hoe/trunk/PKGBUILD
===================================================================
--- ruby-hoe/trunk/PKGBUILD	                        (rev 0)
+++ ruby-hoe/trunk/PKGBUILD	2019-02-03 16:46:04 UTC (rev 429490)
@@ -0,0 +1,39 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Bernhard Landauer <oberon at manjaro.org>
+# Contributor: Alexsandr Pavlov <kidoz at mail dot ru>
+
+_gemname=hoe
+pkgname=ruby-${_gemname}
+_gitcommit=a4cb51d8eaec7d7083cef7b3a83a024cb5a7b9c9
+pkgver=3.17.1
+pkgrel=1
+pkgdesc='Hoe is a rake/rubygems helper for project Rakefiles'
+url='https://www.zenspider.com/projects/hoe.html'
+arch=('any')
+license=('MIT')
+depends=('ruby')
+makedepends=('git' 'ruby-rdoc' 'ruby-rake')
+options=('!emptydirs')
+source=(git+https://github.com/seattlerb/hoe)
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${_gemname}
+  grep 'VERSION = "' lib/hoe.rb|sed -E 's|.*"(.+)"|\1|'
+}
+
+build() {
+  cd ${_gemname}
+  rake gem
+}
+
+package() {
+  cd ${_gemname}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
+}
+
+# vim: ts=2 sw=2 et: