[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Sunday, February 3, 2019 @ 23:30:14
  Author: anthraxx
Revision: 429528

addpkg: ruby-rake-compiler 1.0.7-2

Added:
  ruby-rake-compiler/
  ruby-rake-compiler/repos/
  ruby-rake-compiler/trunk/
  ruby-rake-compiler/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: ruby-rake-compiler/trunk/PKGBUILD
===================================================================
--- ruby-rake-compiler/trunk/PKGBUILD	                        (rev 0)
+++ ruby-rake-compiler/trunk/PKGBUILD	2019-02-03 23:30:14 UTC (rev 429528)
@@ -0,0 +1,38 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+_gemname=rake-compiler
+pkgname=ruby-${_gemname}
+pkgver=1.0.7
+pkgrel=2
+pkgdesc='Rake-based Ruby Extension (C, Java) task generator'
+url='https://github.com/rake-compiler/rake-compiler'
+arch=('any')
+license=('MIT')
+depends=('ruby' 'rubygems' 'ruby-rake')
+makedepends=('ruby-rdoc')
+options=('!emptydirs')
+source=(https://github.com/rake-compiler/rake-compiler/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz)
+sha256sums=('034476284c7caaffcf15f6ba8d94362b14f0289c64488149dd7a08538f0225b4')
+sha512sums=('fa901f5cc48891f07bd8d9a27cf4e745e87d5a667dbee0c9f4b43f9564fdfe3067b9c658f10ea8bcacd32ea7320a542ef0fca9373147057472f5572a4a4c5268')
+
+prepare() {
+  cd ${_gemname}-${pkgver}
+  sed -r 's|~>|>=|g' -i ${_gemname}.gemspec
+}
+
+build() {
+  cd ${_gemname}-${pkgver}
+  gem build ${_gemname}.gemspec
+}
+
+package() {
+  cd ${_gemname}-${pkgver}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" \
+    -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
+  rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rdoc History.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: