[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Monday, February 4, 2019 @ 09:43:05
  Author: anthraxx
Revision: 429560

addpkg: ruby-minitest 5.11.3-2

Added:
  ruby-minitest/
  ruby-minitest/repos/
  ruby-minitest/trunk/
  ruby-minitest/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: ruby-minitest/trunk/PKGBUILD
===================================================================
--- ruby-minitest/trunk/PKGBUILD	                        (rev 0)
+++ ruby-minitest/trunk/PKGBUILD	2019-02-04 09:43:05 UTC (rev 429560)
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Simon Kohlmeyer <simon.kohlmeyer at gmail.com>
+
+_gemname=minitest
+pkgname=ruby-${_gemname}
+_gitcommit=2362e328883ff133140fd8bea5e9ec9a714a7999
+pkgver=5.11.3
+pkgrel=2
+pkgdesc='Complete suite of testing facilities supporting TDD, BDD, mocking, and benchmarking'
+url='https://github.com/seattlerb/minitest'
+arch=('any')
+license=('MIT')
+depends=('ruby')
+makedepends=('git' 'rubygems' 'ruby-rake' 'ruby-rdoc' 'ruby-hoe')
+options=('!emptydirs')
+source=("git+https://github.com/seattlerb/minitest#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${_gemname}
+  grep 'VERSION = "' lib/minitest.rb|sed -E 's|.*"(.+)".*|\1|'
+}
+
+build() {
+  cd ${_gemname}
+  rake gem
+}
+
+check() {
+  cd ${_gemname}
+  rake test
+}
+
+package() {
+  cd ${_gemname}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
+    -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
+  install -Dm 644 README.rdoc History.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm -r "${pkgdir}/${_gemdir}/cache"
+}
+
+# vim: ts=2 sw=2 et: