[arch-commits] Commit in evilginx/repos (community-x86_64 community-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Wednesday, February 6, 2019 @ 19:35:28
  Author: anthraxx
Revision: 429746

archrelease: copy trunk to community-x86_64

Added:
  evilginx/repos/community-x86_64/
  evilginx/repos/community-x86_64/PKGBUILD
    (from rev 429745, evilginx/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: evilginx/repos/community-x86_64/PKGBUILD (from rev 429745, evilginx/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2019-02-06 19:35:28 UTC (rev 429746)
@@ -0,0 +1,40 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: kpcyrd <git at rxv.cc>
+
+pkgname=evilginx
+pkgdesc='Man-in-the-middle attack framework used for phishing login credentials'
+pkgver=2.3.0
+pkgrel=2
+url='https://github.com/kgretzky/evilginx2'
+license=('GPL3')
+arch=('x86_64')
+depends=('glibc')
+makedepends=('go-pie' 'git' 'dep')
+source=(https://github.com/kgretzky/evilginx2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('385926bbd0a37568a4fa9fc9e500bd622a14209ecf0d60ff8b93e6e45b3d59b0649fe9f0c5571f6eade58e025d25a84f24bce9b64a63163939eabdea937bac69')
+
+prepare() {
+  export GOPATH="${srcdir}/go"
+  mkdir -p go/src/github.com/kgretzky
+  ln -rTsf evilginx2-${pkgver} go/src/github.com/kgretzky/evilginx2
+}
+
+build() {
+  cd go/src/github.com/kgretzky/evilginx2
+  export GOPATH="${srcdir}/go"
+  dep ensure -v
+  go build -v \
+    -gcflags "all=-trimpath=${GOPATH}" \
+    -asmflags "all=-trimpath=${GOPATH}" \
+    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
+    -o ./bin/evilginx main.go
+}
+
+package() {
+  cd go/src/github.com/kgretzky/evilginx2
+  install -Dm 755 bin/evilginx -t "${pkgdir}/usr/bin"
+  install -Dm 644 phishlets/* -t "${pkgdir}/usr/share/evilginx/phishlets"
+  install -Dm 644 README.md CHANGELOG -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: