[arch-commits] Commit in lib32-libpsl/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Sun Feb 10 02:50:02 UTC 2019
Date: Sunday, February 10, 2019 @ 02:50:00
Author: foutrelis
Revision: 431052
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-libpsl/repos/multilib-staging-x86_64/
lib32-libpsl/repos/multilib-staging-x86_64/PKGBUILD
(from rev 431051, lib32-libpsl/trunk/PKGBUILD)
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Copied: lib32-libpsl/repos/multilib-staging-x86_64/PKGBUILD (from rev 431051, lib32-libpsl/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2019-02-10 02:50:00 UTC (rev 431052)
@@ -0,0 +1,56 @@
+# Maintainer: Levente Polyak <anthraxx at archlinux.org>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=lib32-libpsl
+pkgver=0.20.2
+pkgrel=3
+pkgdesc='Public Suffix List library (32-bit)'
+url='https://github.com/rockdaboot/libpsl'
+arch=('x86_64')
+license=('MIT')
+depends=('libpsl' 'lib32-glibc' 'lib32-libidn2' 'lib32-libunistring')
+makedepends=('publicsuffix-list' 'python')
+provides=('libpsl.so')
+source=(https://github.com/rockdaboot/libpsl/releases/download/libpsl-${pkgver}/libpsl-${pkgver}.tar.gz)
+sha512sums=('fa9f6f7f0447d9fe00f5dfca5262c56ff26217eea44d0f7fc1e5d982224c41874e753f0aa06dd9e5d7d03d4f04e3dacd4f36034cc8dd0fc6e2c28b49a23e62fe')
+
+prepare() {
+ cd libpsl-${pkgver}
+ rm -frv list
+ autoreconf -fiv
+}
+
+build() {
+ cd libpsl-${pkgver}
+
+ export CC='gcc -m32'
+ export CXX='g++ -m32'
+ export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+ ./configure \
+ --prefix='/usr' \
+ --libdir='/usr/lib32' \
+ --disable-static \
+ --disable-dependency-tracking \
+ --enable-{builtin,runtime}=libidn2 \
+ --with-psl-file='/usr/share/publicsuffix/effective_tld_names.dat' \
+ --with-psl-testfile='/usr/share/publicsuffix/test_psl.txt'
+ LC_CTYPE=en_US.UTF-8 make
+}
+
+check() {
+ cd libpsl-${pkgver}
+ make check
+}
+
+package() {
+ cd libpsl-${pkgver}
+
+ make DESTDIR="${pkgdir}" install
+ rm -rf "${pkgdir}"/usr/{bin,include,share}
+
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s libpsl "${pkgdir}"/usr/share/licenses/lib32-libpsl
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list