[arch-commits] Commit in networkmanager-openconnect/repos (2 files)

[Levente Polyak]

    Date: Tuesday, February 12, 2019 @ 01:15:20
  Author: anthraxx
Revision: 346029

archrelease: copy trunk to staging-x86_64

Added:
  networkmanager-openconnect/repos/staging-x86_64/
  networkmanager-openconnect/repos/staging-x86_64/PKGBUILD
    (from rev 346028, networkmanager-openconnect/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: networkmanager-openconnect/repos/staging-x86_64/PKGBUILD (from rev 346028, networkmanager-openconnect/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-02-12 01:15:20 UTC (rev 346029)
@@ -0,0 +1,48 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=networkmanager-openconnect
+pkgver=1.2.5dev+110+g524a2e0
+pkgrel=2
+pkgdesc="NetworkManager VPN plugin for OpenConnect"
+url="https://wiki.gnome.org/Projects/NetworkManager"
+arch=(x86_64)
+license=(GPL)
+depends=(libnm libsecret openconnect libopenconnect.so)
+makedepends=(libnma intltool python git)
+optdepends=('libnma: GUI support')
+_commit=524a2e0922a69867861ccb5c2f1aef91f45facea  # master
+source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openconnect.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd NetworkManager-openconnect
+  git describe --tags | sed 's/-dev/dev/;s/-/+/g'
+}
+
+prepare() {
+  cd NetworkManager-openconnect
+
+  # Fixup tags
+  git tag -f 1.2.5-dev 8829d0c947707f2c78accc815b83f27d960534cc
+
+  intltoolize --automake --copy
+  autoreconf -fvi
+}
+
+build() {
+  cd NetworkManager-openconnect
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd NetworkManager-openconnect
+  make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
+  echo 'u nm-openconnect - "NetworkManager OpenConnect"' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+}
+
+# vim:set sw=2 et: