[arch-commits] Commit in (4 files)

[Maxim Baz]

    Date: Wednesday, February 13, 2019 @ 02:10:47
  Author: maximbaz
Revision: 432018

yubikey-touch-detector: import from AUR

Added:
  yubikey-touch-detector/
  yubikey-touch-detector/repos/
  yubikey-touch-detector/trunk/
  yubikey-touch-detector/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: yubikey-touch-detector/trunk/PKGBUILD
===================================================================
--- yubikey-touch-detector/trunk/PKGBUILD	                        (rev 0)
+++ yubikey-touch-detector/trunk/PKGBUILD	2019-02-13 02:10:47 UTC (rev 432018)
@@ -0,0 +1,39 @@
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+
+pkgname=yubikey-touch-detector
+pkgver=1.2.0
+pkgrel=1
+pkgdesc='A tool that can detect when your YubiKey is waiting for a touch'
+arch=('x86_64')
+url='https://github.com/maximbaz/yubikey-touch-detector'
+license=('MIT')
+depends=('glibc')
+makedepends=('go-pie')
+optdepends=('gnupg: for GPG'
+            'openssh: for SSH'
+            'pam_u2f: for U2F')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/releases/download/${pkgver}/${pkgname}-src.tar.gz"
+        "${pkgname}-${pkgver}.tar.gz.sig::${url}/releases/download/${pkgver}/${pkgname}-src.tar.gz.sig")
+sha256sums=('9f15f435bcb898f001e159ef107861d5c41dbe6828f1b22734abc30444e7c207'
+            'SKIP')
+validpgpkeys=('EB4F9E5A60D32232BB52150C12C87A28FEAC6B20')
+
+prepare() {
+    mkdir -p "gopath/src/github.com/maximbaz"
+    ln -rTsf "${pkgname}" "gopath/src/github.com/maximbaz/${pkgname}"
+}
+
+build() {
+    export GOPATH="${srcdir}/gopath"
+    cd "gopath/src/github.com/maximbaz/${pkgname}"
+    make build
+}
+
+package() {
+    cd "${pkgname}"
+    install -Dm755 -t "${pkgdir}/usr/bin" "${pkgname}"
+    install -Dm644 -t "${pkgdir}/usr/lib/systemd/user" "${pkgname}.service"
+    install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
+}
+
+# vim:set ts=4 sw=4 et: