[arch-commits] Commit in gpaste/repos/extra-x86_64 (PKGBUILD)

[Jan Steffens]

    Date: Friday, February 15, 2019 @ 17:37:22
  Author: heftig
Revision: 346321

archrelease: copy trunk to extra-x86_64

Added:
  gpaste/repos/extra-x86_64/PKGBUILD
    (from rev 346320, gpaste/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: gpaste/repos/extra-x86_64/PKGBUILD (from rev 346320, gpaste/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2019-02-15 17:37:22 UTC (rev 346321)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=gpaste
+pkgver=3.30.2
+pkgrel=2
+pkgdesc="Clipboard management system"
+url="https://www.imagination-land.org/tags/GPaste.html"
+license=(BSD)
+arch=(x86_64)
+depends=(gtk3)
+makedepends=(intltool vala appstream-glib gobject-introspection gnome-shell gnome-control-center git)
+optdepends=("wgetpaste: Upload clipboard contents")
+_commit=a8bdf028bb94d1d7d91e6396b00f4b0a0c5e2fa4  # tags/v3.30.2^0
+source=("git+https://github.com/keruspe/gpaste#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libexecdir=/usr/lib --sysconfdir=/etc \
+    --enable-vala
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" COPYING
+}