[arch-commits] Commit in openal/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Sunday, February 17, 2019 @ 09:39:07
  Author: arojas
Revision: 346409

archrelease: copy trunk to staging-x86_64

Added:
  openal/repos/staging-x86_64/
  openal/repos/staging-x86_64/PKGBUILD
    (from rev 346408, openal/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: openal/repos/staging-x86_64/PKGBUILD (from rev 346408, openal/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2019-02-17 09:39:07 UTC (rev 346409)
@@ -0,0 +1,59 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jason Chu <jchu at xentac.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.19.1
+pkgrel=2
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL)
+depends=(glibc)
+makedepends=(alsa-lib libpulse fluidsynth portaudio jack qt5-base sdl2 sdl_sound ffmpeg
+             git cmake ninja)
+_commit=6761218e51699f46bf25c377e65b3e9ea5e434b9  # tags/openal-soft-1.19.1
+source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd openal-soft
+  git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
+}
+
+prepare() {
+  mkdir build examples
+  cd openal-soft
+  git cherry-pick -n 8bacb5dfb8ef910586fcf5b5cd89526ec81061e8
+}
+
+build() {
+  cd build
+  cmake ../openal-soft -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  ninja
+}
+
+package_openal() {
+  optdepends=('qt5-base: alsoft-config GUI Configurator'
+              'fluidsynth: MIDI rendering')
+
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
+
+### Split openal-examples
+  cd "$pkgdir/usr/bin"
+  mv -vt "$srcdir/examples" alffplay alhrtf allatency alloopback almultireverb \
+    alplay alrecord alreverb alstream altonegen
+}
+
+package_openal-examples() {
+  pkgdesc+=" (example programs)"
+  depends=("openal=$pkgver-$pkgrel" sdl2 sdl_sound ffmpeg)
+
+  mkdir "$pkgdir/usr"
+  mv -v examples "$pkgdir/usr/bin"
+}