[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, February 22, 2019 @ 20:50:47
  Author: felixonmars
Revision: 435336

addpkg: golang-github-boombuler-barcode 1.0.0.20190219-1

Added:
  golang-github-boombuler-barcode/
  golang-github-boombuler-barcode/repos/
  golang-github-boombuler-barcode/trunk/
  golang-github-boombuler-barcode/trunk/PKGBUILD

----------+
 PKGBUILD |   28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)

Added: golang-github-boombuler-barcode/trunk/PKGBUILD
===================================================================
--- golang-github-boombuler-barcode/trunk/PKGBUILD	                        (rev 0)
+++ golang-github-boombuler-barcode/trunk/PKGBUILD	2019-02-22 20:50:47 UTC (rev 435336)
@@ -0,0 +1,28 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=golang-github-boombuler-barcode
+pkgver=1.0.0.20190219
+_commit=6c824513baccd76c674ce72112c29ef550187b08
+pkgrel=1
+pkgdesc='A barcode creation lib for golang'
+arch=('any')
+url="https://github.com/boombuler/barcode"
+license=('MIT')
+depends=('go-pie')
+source=("$pkgname-$_commit.tar.gz::https://github.com/boombuler/barcode/archive/$_commit.tar.gz")
+sha512sums=('441703efde7dac4689b95f8d521947796563d7310b95cd00bb9de57dca997cd42d1a9f06453d60d06076c03792e4f5cd2eecc9450612de3ff830a82dadfccbef')
+
+check() {
+  export GOPATH="$srcdir/build:/usr/share/gocode"
+  mkdir -p "$srcdir"/build/src/github.com/boombuler
+  cp -a "$srcdir"/barcode-$_commit "$srcdir"/build/src/github.com/boombuler/barcode
+  cd "$srcdir"/build/src/github.com/boombuler/barcode
+  go test -v $(go list ./... | grep -v vendor)
+}
+
+package() {
+  mkdir -p "$pkgdir"/usr/share/gocode/src/github.com/boombuler
+  cp -a "$srcdir"/barcode-$_commit "$pkgdir"/usr/share/gocode/src/github.com/boombuler/barcode
+
+  install -Dm644 barcode-$_commit/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}